iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion lugares como
    inicio
       si junto-a-zumbador entonces
       inicio
           repetir 2 veces si junto-a-zumbador entonces coge-zumbador;
           norte;
           si no-junto-a-zumbador y frente-libre entonces
           inicio
               avanza;
               lugares;
               sur;
               avanza;
           fin;
           sur;
           si no-junto-a-zumbador y frente-libre entonces
           inicio
               avanza;
               lugares;
               norte;
               avanza;
           fin;
           este;
           si no-junto-a-zumbador y frente-libre entonces
           inicio
               avanza;
               lugares;
               oeste;
               avanza;
           fin;
           oeste;
           si no-junto-a-zumbador y frente-libre entonces
           inicio
               avanza;
               lugares;
               este;
               avanza;
           fin;
        fin;
    fin;

    define-nueva-instruccion peces como
    inicio
        si algun-zumbador-en-la-mochila entonces
        inicio
            deja-zumbador;
            peces;
            repetir 2 veces coge-zumbador;
         fin;
    fin;

    define-nueva-instruccion area(n) como
    inicio
        si algun-zumbador-en-la-mochila entonces
        inicio
            deja-zumbador;
            area(sucede(n));
        fin sino
        inicio
            repetir n veces coge-zumbador;
            lugares;
            sur;
            mientras frente-libre hacer avanza;
            oeste;
            mientras frente-libre hacer avanza;
            norte;
            repetir 2 veces
            inicio
                repetir n veces deja-zumbador;
            fin;
            peces;
            repetir n veces coge-zumbador;
        fin;
    fin;

    inicia-ejecucion
        area(0);
        apagate;
    termina-ejecucion
finalizar-programa

