iniciar-programa
define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion ir11 como
  inicio
    sur;
    mientras frente-libre hacer avanza;
    oeste;
    mientras frente-libre hacer avanza;
  fin;

define-nueva-instruccion recoger como
  inicio
    si junto-a-zumbador entonces
      inicio
       repetir 2 veces si junto-a-zumbador entonces coge-zumbador;
               norte;
        si frente-libre entonces
          inicio
            avanza;
            recoger;
            sur;
            avanza;
          fin;

         sur;
        si frente-libre entonces
          inicio
            avanza;
            recoger;
            norte;
            avanza;
          fin;

         este;
        si frente-libre entonces
          inicio
            avanza;
            recoger;
            oeste;
            avanza;
          fin;

         oeste;
        si frente-libre entonces
          inicio
            avanza;
            recoger;
            este;
            avanza;
          fin;
      fin;
  fin;

define-nueva-instruccion sobrante(n) como
  inicio
   si algun-zumbador-en-la-mochila entonces
     inicio
       deja-zumbador;
       sobrante(sucede(n));
     fin
   sino
     inicio
       repetir n veces
         inicio
           repetir 2 veces coge-zumbador;
         fin;
     fin;
  fin;

define-nueva-instruccion area(n) como
  inicio
    si algun-zumbador-en-la-mochila entonces
      inicio
        deja-zumbador;
        area(sucede(n));
      fin
    sino
      inicio
        repetir n veces coge-zumbador;
        recoger;
        ir11;
        repetir n veces deja-zumbador;
        repetir n veces deja-zumbador;
        sobrante(0);
        repetir n veces coge-zumbador;
      fin;
  fin;
    inicia-ejecucion
          area(0);
        apagate;
    termina-ejecucion
finalizar-programa
