iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
    fin;

    define-nueva-instruccion deja como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            deja-zumbador;
            deja;
            coge-zumbador;
            coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion busqueda como inicio
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                busqueda;
                sur;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                busqueda;
                norte;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                busqueda;
                oeste;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                busqueda;
                este;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion rio(n) como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            deja-zumbador;
            rio(sucede(n));
        fin sino inicio
            repetir n veces inicio
                coge-zumbador;
            fin;
            busqueda;
            ir11;
            repetir 2 veces inicio
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin;
            deja;
            repetir n veces inicio
                coge-zumbador;
            fin;    
            apagate;
        fin;
    fin;

    inicia-ejecucion
        rio(0);
        apagate;
    termina-ejecucion
finalizar-programa
