iniciar-programa

    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;

    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;

    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion pared2 como inicio
        si frente-libre entonces inicio
            avanza;
            pared2;
            avanza;
        fin sino inicio
            deja-zumbador;
            gira(2);
        fin;
    fin;

    define-nueva-instruccion pared como inicio
        si frente-libre entonces inicio
            avanza;
            pared;
            avanza;
        fin sino inicio
            gira(1);
            pared2;
            gira(3);
        fin;
    fin;

    define-nueva-instruccion busqueda como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                sur;
                si (frente-bloqueado y derecha-bloqueada) entonces inicio
                    repetir 2 veces deja-zumbador;
                fin;
            fin sino inicio
                oeste;
                pared;
            fin;
            norte;
            si frente-libre entonces inicio
                avanza;
                busqueda;
                sur;
                avanza;
            fin;

            sur;
            si frente-libre entonces inicio
                avanza;
                busqueda;
                norte;
                avanza;
            fin;

            este;
            si frente-libre entonces inicio
                avanza;
                busqueda;
                oeste;
                avanza;
            fin;

            oeste;
            si frente-libre entonces inicio
                avanza;
                busqueda;
                este;
                avanza;
            fin;
        fin;
    fin;

    inicia-ejecucion
        busqueda;
        apagate;
    termina-ejecucion
finalizar-programa
