iniciar-programa
    define-prototipo-instruccion buscar;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion orientar como inicio
        norte;
        si frente-libre entonces inicio
            avanza;
            buscar;
            sur;
            avanza;
        fin;

        sur;
        si frente-libre entonces inicio
            avanza;
            buscar;
            norte;
            avanza;
        fin;

        este;
        si frente-libre entonces inicio
            avanza;
            buscar;
            oeste;
            avanza;
        fin;

        oeste;
        si frente-libre entonces inicio
            avanza;
            buscar;
            este;
            avanza;
        fin;
    fin;

    define-nueva-instruccion buscar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    repetir 2 veces deja-zumbador;
                    fin sino inicio
                    repetir 3 veces deja-zumbador;
                    orientar;
                    fin;
            fin sino inicio
                orientar;
            fin;
        fin;
    fin;

    define-nueva-instruccion ir_inicio como inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
        norte;
    fin;

    define-nueva-instruccion dejar_mitad como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            repetir 2 veces deja-zumbador;
            dejar_mitad;
            coge-zumbador;
        fin;
    fin;
    inicia-ejecucion
        norte;
        buscar;
        ir_inicio;
        dejar_mitad;
        apagate;
    termina-ejecucion
finalizar-programa
