iniciar-programa
  define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
  define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
  define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
  define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
  define-nueva-instruccion al-frente como mientras frente-libre hacer avanza;

  define-nueva-instruccion camina como inicio
      si frente-libre entonces inicio
          avanza;
      fin sino inicio
          si izquierda-libre entonces inicio
              gira-izquierda;
              avanza;
              oeste;
              al-frente;
              este;
          fin sino inicio
              sur;
          fin;
      fin;
  fin;




  define-nueva-instruccion cubeta como inicio
      si junto-a-zumbador entonces inicio
          coge-zumbador;
          cubeta;
          avanza;
      fin sino inicio
          oeste;
          al-frente;
          sur;
          al-frente;
          este;
      fin;
  fin;
  define-nueva-instruccion siguiente-zum como inicio
      mientras no-junto-a-zumbador y no-orientado-al-sur hacer inicio
          camina;
      fin;
  fin;
  define-nueva-instruccion ve-bolsa como inicio
      oeste;
      al-frente;
      sur;
      al-frente;
      norte;
      repetir 2 veces avanza;
      este;
  fin;
  define-nueva-instruccion proceso-juntar como inicio
      mientras no-orientado-al-sur hacer inicio
          ve-bolsa;
          siguiente-zum;
          si junto-a-zumbador entonces inicio
              coge-zumbador;
              cubeta;
              deja-zumbador;
          fin;
      fin;
  fin;



  define-nueva-instruccion acarrea como inicio
      si junto-a-zumbador entonces inicio
          coge-zumbador;
          acarrea;
          deja-zumbador;
      fin sino inicio
          norte;
          avanza;
      fin;
  fin;
  define-nueva-instruccion compara(n) como inicio
      si junto-a-zumbador y no si-es-cero (n) entonces inicio
          coge-zumbador;
          compara(precede(n));
      fin sino inicio
          si si-es-cero (n) entonces inicio
                  (*EL TIPO DE DULCE CABE POR LO MENOS UNA VEZ*)
              norte;
              avanza;
              deja-zumbador;
              sur;
              avanza;
              acarrea;
              sur;
              avanza;
              este;
              si frente-libre entonces avanza;
          fin sino inicio
                   (*EL TIPO DE DULCE ES MUY POCO Y NO CALCANZA PARA PREMIAR*)
              este;
              si frente-libre entonces avanzA;
          fin;
      fin;
  fin;
  define-nueva-instruccion lee-k(n) como inicio
      si junto-a-zumbador entonces inicio
          coge-zumbador;
          lee-k(sucede(n));
      fin sino inicio
          sur;
          avanza;
          este;
          si no si-es-cero (n) entonces inicio
              mientras frente-libre hacer inicio
                  compara(n)
              fin;
          fin sino inicio
              mientras junto-a-zumbador hacer coge-zumbador;
              apagate;
          fin;
      fin;
  fin;
  define-nueva-instruccion proceso-contar como inicio
      oeste;
      al-frente;
      sur;
      al-frente;
      norte;
      avanza;
      lee-k(0);
  fin;




  define-nueva-instruccion suma-linea como inicio
      si frente-libre entonces inicio
          si junto-a-zumbador entonces inicio
              coge-zumbador;
              suma-linea;
              deja-zumbador;
          fin sino inicio
              avanza;
              suma-linea;
          fin;
      fin;
  fin;
  define-nueva-instruccion proceso-sumar como inicio
      norte;
      avanza;
      oeste;
      suma-linea;
      si junto-a-zumbador entonces coge-zumbador;
  fin;



  define-nueva-instruccion resta(n) como inicio
      si junto-a-zumbador entonces inicio
          coge-zumbador;
          resta(precede(n));
      fin sino inicio
          sur;
          avanza;
          repetir n veces deja-zumbador;
      fin;
  fin;
  define-nueva-instruccion proceso-responder(n) como inicio
      resta(n);
  fin;


  define-nueva-instruccion num-dulces(n) como inicio
      si frente-libre o izquierda-libre entonces inicio
          si junto-a-zumbador entonces inicio
              camina;
              num-dulces(sucede(n));
          fin sino inicio
              camina;
              num-dulces(n);
          fin;
      fin sino inicio
          si junto-a-zumbador entonces inicio
                   (*TENGO N +1 TIPOS DE DULCE*)
              proceso-juntar;
              proceso-contar;
              proceso-sumar;
              proceso-responder(sucede(n));
          fin sino inicio
                   (*TENGO N TIPOS DE DULCE*)
              proceso-juntar;
              proceso-contar;
              proceso-sumar;
              proceso-responder(n);

          fin;
      fin;
  fin;
    inicia-ejecucion
        norte;
        repetir 2 veces avanza;
        este;
        num-dulces(0);
        apagate;
    termina-ejecucion
finalizar-programa
