iniciar-programa
    define-nueva-instruccion gira-derecha como inicio
        gira-izquierda;
        gira-izquierda;
        gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion deja-dulces como inicio
        gira-izquierda;
        gira-izquierda;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        gira-izquierda;
        avanza;
        mientras junto-a-zumbador hacer inicio
            avanza;
        fin;
        gira-izquierda;
    fin;
    define-nueva-instruccion camina2 como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            gira-izquierda;
            gira-izquierda;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            gira-derecha;
            si frente-libre entonces inicio
                avanza;
                gira-derecha;
            fin sino inicio
                deja-dulces;
            fin;
        fin;
    fin;
    define-nueva-instruccion compara(n) como inicio
        si junto-a-zumbador entonces inicio
            si no si-es-cero(n) entonces inicio
                coge-zumbador;
                compara(precede(n));
                deja-zumbador;
            fin sino inicio
                mientras no orientado-al-norte hacer inicio
                    gira-izquierda;
                fin;
            fin;
        fin sino inicio
            si no si-es-cero(n) entonces inicio
                mientras no orientado-al-norte hacer inicio
                    gira-izquierda;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion busca-otros(n) como inicio
        si junto-a-zumbador entonces inicio
            compara(n);
            si orientado-al-norte entonces inicio
                gira-derecha;
                camina2;
                si no-orientado-al-norte entonces inicio
                    busca-otros(n);
                fin;
            fin sino inicio
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                fin;
                camina2;
                si no-orientado-al-norte entonces inicio
                    busca-otros(n);
                fin;
                deja-zumbador;
            fin;
        fin sino inicio
            camina2;
            si no-orientado-al-norte entonces inicio
                busca-otros(n);
            fin;
        fin;
    fin;
    define-nueva-instruccion cuenta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(n));
        fin sino inicio
            busca-otros(n);
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion regresa como inicio
        gira-izquierda;
        gira-izquierda;
        mientras frente-libre hacer inicio
            avanza;
        fin;
    fin;
    define-nueva-instruccion camina como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            gira-izquierda;
            gira-izquierda;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            gira-derecha;
            si frente-libre entonces inicio
                avanza;
                gira-derecha;
            fin sino inicio
                regresa;
            fin;
        fin;
    fin;
    define-nueva-instruccion busca-primero(n) como inicio
        si no-junto-a-zumbador entonces inicio
            camina;
            si orientado-al-este entonces inicio
                busca-primero(n);
            fin;
        fin sino inicio
            cuenta(n);
        fin;
    fin;
    define-nueva-instruccion ubicate como inicio
        mientras no-orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        gira-derecha;
        avanza;
        avanza;
        gira-derecha;
    fin;
    define-nueva-instruccion desecha como inicio
        gira-izquierda;
        avanza;
        gira-izquierda;
        avanza;
        mientras algun-zumbador-en-la-mochila hacer inicio
            deja-zumbador;
        fin;
        gira-izquierda;
        avanza;
    fin;
    define-nueva-instruccion ordenar-dulces(n) como inicio
        mientras orientado-al-norte hacer inicio
            ubicate;
            busca-primero(0);
        fin;
        desecha;
    fin;
    define-nueva-instruccion saca-dulces(n) como inicio
        mientras junto-a-zumbador hacer inicio
            repetir n veces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin;
            fin;
            avanza;
        fin;
        gira-izquierda;
        gira-izquierda;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        mientras algun-zumbador-en-la-mochila hacer inicio
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion alumnos(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            alumnos(sucede(n));
        fin sino inicio
            repetir n veces inicio
                deja-zumbador;
            fin;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
            fin;
            gira-izquierda;
            avanza;
            gira-izquierda;
            avanza;
            si no si-es-cero(n) entonces inicio
                saca-dulces(precede(n));
            fin;
        fin;
    fin;
    inicia-ejecucion
        norte;
        ordenar-dulces(0);
        alumnos(0);
        apagate;
    termina-ejecucion
finalizar-programa
