iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion recoge(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoge(sucede(x));
        fin sino inicio
            oeste;
            corre;
            sur;
            corre;
            este;
            repetir x veces avanza;
            deja-zumbador;
            oeste;
            corre;
            norte;
            repetir 2 veces avanza;
            este;
        fin;
    fin;
    define-nueva-instruccion camina como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            oeste;
            corre;
            norte;
            si frente-libre entonces inicio
                avanza;
                este;
            fin sino inicio
                sur;
            fin;
        fin;
    fin;
    define-nueva-instruccion cubeta como inicio
        mientras no-orientado-al-sur hacer inicio
            si junto-a-zumbador entonces inicio
                recoge(0);
            fin sino inicio
                camina;
            fin;
        fin;
    fin;
    define-nueva-instruccion suma(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            suma(sucede(x));
        fin sino inicio
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            sur;
            avanza;
            este;
            avanza;
            mientras no-orientado-al-oeste hacer inicio
                si junto-a-zumbador entonces inicio
                    repetir precede(x) veces si junto-a-zumbador entonces coge-zumbador;
                    mientras junto-a-zumbador hacer coge-zumbador;
                    oeste;
                    corre;
                    repetir precede(x)veces si algun-zumbador-en-la-mochila entonces deja-zumbador;
                    norte;
                    avanza;
                    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                    sur;
                    avanza;
                    este;
                    avanza;
                fin sino inicio
                    si frente-libre entonces inicio
                        avanza;
                    fin sino inicio
                        oeste;
                    fin;
                fin;
            fin;
        fin;
    fin;
    inicia-ejecucion
        norte;
        repetir 2 veces avanza;
        este;
        cubeta;
        corre;
        norte;
        avanza;
        suma(0);
        corre;
        norte;
        avanza;
        coge-zumbador;
        sur;
        avanza;
        deja-zumbador;
        apagate;
    termina-ejecucion
finalizar-programa
