iniciar-programa
define-nueva-instruccion gira(q) como repetir q veces gira-izquierda;
define-nueva-instruccion pasa como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        pasa;
        deja-zumbador;
    fin sino inicio
        gira(2);
        avanza;
        gira(2);
    fin;
fin;

define-nueva-instruccion busca como inicio
    mientras no junto-a-zumbador y frente-libre hacer avanza;
    si no junto-a-zumbador entonces inicio
        gira(1);
        si frente-libre entonces inicio
            avanza;
            gira(1);
            mientras frente-libre hacer avanza;
            gira(2);
            busca;
        fin sino inicio
            gira(2);
        fin;
    fin;
fin;

define-nueva-instruccion tam como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        tam;
        avanza;
    fin sino inicio
        mientras no orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(1);
        mientras frente-libre hacer avanza;
        gira(2);
        avanza;
        gira(3);
    fin;
fin;

define-nueva-instruccion cuenta(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        cuenta(sucede(x));
    fin sino inicio
        gira(1);
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        gira(2);
        coge-zumbador;
        avanza;
        gira(3);
        avanza;
        gira(3);
        repetir x veces inicio
            mientras orientado-al-este hacer inicio
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                si junto-a-zumbador entonces coge-zumbador;
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    gira(2);
                fin;
            fin;
            mientras frente-libre hacer avanza;
            gira(2);
        fin;
        gira(3);
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
    fin;
fin;

    inicia-ejecucion
    mientras no orientado-al-norte hacer gira-izquierdA;
    avanza;
    si junto-a-zumbador entonces inicio
        pasa;
        mientras no orientado-al-sur hacer inicio
            repetir 2 veces avanza;
            gira(3);
            busca;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                tam;
                deja-zumbador;
                gira(2);
                mientras frente-libre hacer avanza;
                gira(1);
                avanza;
                gira(2);
            fin sino inicio
                gira(3);
                mientras frente-libre hacer avanza;
                gira(1);
                mientras frente-libre hacer avanza;
            fin;
        fin;
        coge-zumbador;
        cuenta(0);
    fin;
    apagate;
    termina-ejecucion
finalizar-programa
