iniciar-programa
    define-nueva-instruccion gira(n) como inicio
       repetir n veces
          gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
       mientras no-orientado-al-norte hacer
          gira(1);
    fin;
    define-nueva-instruccion sur como inicio
       mientras no-orientado-al-sur hacer
          gira(1);
    fin;
    define-nueva-instruccion este como inicio
       mientras no-orientado-al-este hacer
          gira(1);
    fin;
    define-nueva-instruccion oeste como inicio
       mientras no-orientado-al-oeste hacer
          gira(1);
    fin;
    define-nueva-instruccion cubeta(n) como inicio
       si junto-a-zumbador entonces inicio
          coge-zumbador;
          cubeta(sucede(n));
       fin
       sino inicio
          oeste;
          mientras frente-libre hacer
             avanza;
          sur;
          mientras frente-libre hacer
             avanza;
          este;
          repetir precede(n) veces
             avanza;
          deja-zumbador;
          oeste;
          mientras frente-libre hacer
             avanza;
          norte;
          avanza;
          avanza;
          este;
       fin;
    fin;
    define-nueva-instruccion compara(n) como inicio
       si junto-a-zumbador y no si-es-cero(n) entonces inicio
          coge-zumbador;
          compara(precede(n));
          deja-zumbador;
       fin
       sino inicio
          si junto-a-zumbador y si-es-cero(n) entonces inicio
             norte;
          fin
          sino inicio
             si no si-es-cero(n) entonces inicio
                sur;
             fin;
          fin;
       fin;
    fin;
    define-nueva-instruccion pasa(n) como inicio
       si junto-a-zumbador entonces inicio
          coge-zumbador;
          pasa(sucede(n));
       fin
       sino inicio
          oeste;
          mientras frente-libre hacer
             avanza;
          norte;
          avanza;
          repetir n veces
             deja-zumbador;
          sur;
          avanza;
       fin;
    fin;
    define-nueva-instruccion cuenta(n) como inicio
       si junto-a-zumbador entonces inicio
          coge-zumbador;
          cuenta(sucede(n));
       fin
       sino inicio
          sur;
          avanza;
          si si-es-cero(n) entonces inicio
             mientras junto-a-zumbador hacer
                coge-zumbador;
             apagate;
          fin;
          este;
          mientras frente-libre hacer inicio
             si junto-a-zumbador entonces inicio
                compara(n);
                si orientado-al-sur entonces inicio
                   pasa(0);
                fin
                sino inicio
                   mientras junto-a-zumbador hacer
                      coge-zumbador;
                   oeste;
                   mientras frente-libre hacer
                      avanza;
                   norte;
                   avanza;
                   repetir precede(n) veces
                      deja-zumbador;
                   sur;
                   avanza;
                fin;
                este;
             fin;
             avanza;
          fin;
       fin;
    fin;
    define-nueva-instruccion proceso como inicio
       mientras no-orientado-al-sur hacer inicio
          si junto-a-zumbador entonces inicio
             cubeta(0);
          fin;
          si frente-libre entonces inicio
             avanza;
          fin
          sino inicio
             norte;
             si frente-libre entonces inicio
                avanza;
                oeste;
                mientras frente-libre hacer
                   avanza;
                este;
             fin
             sino inicio
                sur;
             fin;
          fin;
       fin;
       oeste;
       mientras frente-libre hacer
          avanza;
       sur;
       mientras frente-libre hacer
          avanza;
       norte;
       avanza;
       cuenta(0);
       oeste;
       mientras frente-libre hacer
          avanza;
    fin;
    define-nueva-instruccion termina como inicio
       si junto-a-zumbador entonces inicio
          coge-zumbador;
          termina;
          deja-zumbador;
       fin
       sino inicio
          sur;
          avanza;
          deja-zumbador;
       fin;
    fin;
    define-nueva-instruccion inicia como inicio
       norte;
       avanza;
       avanza;
       este;
       proceso;
       norte;
       avanza;
       termina;
    fin;
    inicia-ejecucion
       inicia;
       apagate;
    termina-ejecucion
finalizar-programa