iniciar-programa
    define-nueva-instruccion gira(n) como inicio
       repetir n veces
          gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
       mientras no-orientado-al-norte hacer
          gira(1);
    fin;
    define-nueva-instruccion sur como inicio
       mientras no-orientado-al-sur hacer
          gira(1);
    fin;
    define-nueva-instruccion este como inicio
       mientras no-orientado-al-este hacer
          gira(1);
    fin;
    define-nueva-instruccion oeste como inicio
       mientras no-orientado-al-oeste hacer
          gira(1);
    fin;
    define-nueva-instruccion es_arbol como inicio
       si izquierda-bloqueada entonces inicio
          avanza;
          si izquierda-bloqueada entonces inicio
             avanza;
             si izquierda-bloqueada entonces inicio
                oeste;
                avanza;
                avanza;
                sur;
             fin
             sino inicio
                oeste;
                avanza;
                avanza;
                este;
             fin;
          fin
          sino inicio
             oeste;
             avanza;
             este;
          fin;
       fin;
    fin;
    define-nueva-instruccion revisa como inicio
       oeste;
       si frente-libre entonces inicio
          avanza;
          sur;
          si frente-libre entonces inicio
             avanza;
             si junto-a-zumbador entonces inicio
                norte;
                avanza;
                este;
                avanza;
                sur;
             fin
             sino inicio
                norte;
                avanza;
                este;
                avanza;
             fin;
          fin
          sino inicio
             este;
             avanza;
          fin;
       fin;
       si no-orientado-al-sur entonces inicio
           este;
           si frente-libre entonces inicio
              avanza;
              sur;
              si frente-libre entonces inicio
                 avanza;
                 si junto-a-zumbador entonces inicio
                    norte;
                    avanza;
                    oeste;
                    avanza;
                    sur;
                 fin
                 sino inicio
                    norte;
                    avanza;
                    oeste;
                    avanza;
                 fin;
              fin
              sino inicio
                 oeste;
                 avanza;
              fin;
           fin;
       fin;
    fin;
    define-nueva-instruccion sube(n) como inicio
       si junto-a-zumbador entonces inicio
          coge-zumbador;
          sube(sucede(n));
       fin
       sino inicio
          repetir n veces
             deja-zumbador;
          avanza;
          norte;
          avanza;
          repetir n veces
             deja-zumbador;
       fin;
    fin;
    define-nueva-instruccion trae como inicio
       oeste;
       si frente-libre entonces inicio
          avanza;
          sur;
          si frente-libre entonces inicio
             avanza;
             este;
             sube(0);
          fin
          sino inicio
             este;
             avanza;
          fin;
       fin;
       este;
       si frente-libre entonces inicio
          avanza;
          sur;
          si frente-libre entonces inicio
             avanza;
             oeste;
             sube(0);
          fin
          sino inicio
             oeste;
             avanza;
          fin;
       fin;
    fin;
    define-nueva-instruccion precio como inicio
       si junto-a-zumbador entonces inicio
          oeste;
          si frente-libre entonces inicio
             avanza;
             sur;
             si frente-libre entonces inicio
                avanza;
                precio;
                norte;
                avanza;
             fin;
             este;
             avanza;
          fin;
          este;
          si frente-libre entonces inicio
             avanza;
             sur;
             si frente-libre entonces inicio
                avanza;
                precio;
                norte;
                avanza;
             fin;
             oeste;
             avanza;
          fin;
          revisa;
          si orientado-al-sur entonces inicio
             mientras junto-a-zumbador hacer
                coge-zumbador;
             trae;
          fin;
       fin;
    fin;
    define-nueva-instruccion hojas como inicio
       si junto-a-zumbador entonces inicio
          oeste;
          si frente-libre entonces inicio
             avanza;
             sur;
             si frente-libre entonces inicio
                avanza;
                hojas;
                norte;
                avanza;
             fin;
             este;
             avanza;
          fin;
          este;
          si frente-libre entonces inicio
             avanza;
             sur;
             si frente-libre entonces inicio
                avanza;
                hojas;
                norte;
                avanza;
             fin;
             oeste;
             avanza;
          fin;
          revisa;
          si orientado-al-sur entonces inicio
             mientras junto-a-zumbador hacer
                coge-zumbador;
             trae;
          fin
          sino inicio
             mientras junto-a-zumbador hacer
                coge-zumbador;
             deja-zumbador;
          fin;
       fin;
    fin;
    define-nueva-instruccion pasa(n) como inicio
       si junto-a-zumbador entonces inicio
          coge-zumbador;
          pasa(sucede(n));
          deja-zumbador;
       fin
       sino inicio
          repetir n veces
             deja-zumbador;
          avanza;
          este;
       fin;
    fin;
    define-nueva-instruccion compara(n) como inicio
       si junto-a-zumbador y no si-es-cero(n) entonces inicio
          coge-zumbador;
          compara(precede(n));
          deja-zumbador;
       fin
       sino inicio
          si si-es-cero(n) entonces inicio
             norte;
          fin
          sino inicio
             sur;
          fin;
       fin;
    fin;
    define-nueva-instruccion cuenta(n) como inicio
       si junto-a-zumbador entonces inicio
          coge-zumbador;
          cuenta(sucede(n));
       fin
       sino inicio
          oeste;
          mientras frente-libre hacer
             avanza;
          compara(n);
          si orientado-al-norte entonces inicio
             mientras junto-a-zumbador hacer
                coge-zumbador;
             repetir n veces
                deja-zumbador;
          fin;
       fin;
    fin;
    define-nueva-instruccion finaliza(n) como inicio
       si junto-a-zumbador entonces inicio
          coge-zumbador;
          finaliza(sucede(n));
       fin
       sino inicio
          repetir 400 veces
             deja-zumbador;
           este;
           avanza;
           mientras frente-libre hacer inicio
              si junto-a-zumbador entonces inicio
                 sur;
                 avanza;
                 compara(n);
                 si orientado-al-norte entonces inicio
                    avanza;
                    cuenta(0);
                    este;
                    avanza;
                 fin
                 sino inicio
                    norte;
                    avanza;
                    este;
                    avanza;
                 fin;
              fin;
              avanza;
           fin;
       fin;
    fin;
    define-nueva-instruccion inicia como inicio
       este;
       si frente-libre entonces inicio
          avanza;
       fin
       sino inicio
          mientras junto-a-zumbador hacer
             coge-zumbador;
          apagate;
       fin;
       mientras frente-libre hacer inicio
          mientras junto-a-zumbador hacer
             coge-zumbador;
          avanza;
       fin;
       oeste;
       mientras frente-libre hacer
          avanza;
       este;
       mientras frente-libre hacer inicio
          si izquierda-libre entonces inicio
             avanza;
          fin
          sino inicio
             es_arbol;
             si orientado-al-sur entonces inicio
                este;
                avanza;
                sur;
                avanza;
                precio;
                norte;
                pasa(0);
                avanza;
                avanza;
             fin
             sino inicio
                este;
                avanza;
             fin;
          fin;
       fin;
       oeste;
       mientras frente-libre hacer
          avanza;
       este;
       avanza;
       mientras frente-libre hacer inicio
          si junto-a-zumbador entonces inicio
             sur;
             avanza;
             hojas;
             norte;
             avanza;
             este;
             avanza;
          fin;
          avanza;
       fin;
       oeste;
       mientras frente-libre hacer
          avanza;
       este;
       finaliza(0);
       oeste;
       mientras frente-libre hacer
          avanza;
       compara(400);
       si orientado-al-norte entonces inicio
          mientras junto-a-zumbador hacer
             coge-zumbador;
       fin;
       este;
    fin;
    inicia-ejecucion
        inicia;
        apagate;
    termina-ejecucion
finalizar-programa