iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion take(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            take(sucede(n));
        fin sino inicio
            oeste;
            deja-zumbador;
            mientras frente-libre hacer avanza;
            norte;
            deja-zumbador;
            mientras frente-libre hacer avanza;
            este;
            avanza;
            repetir n veces deja-zumbador;
            sur;
            avanza;
            si junto-a-zumbador entonces coge-zumbador;
            oeste;
            avanza;
            sur;
            mientras no junto-a-zumbador hacer avanza;
            coge-zumbador;
            este;
            mientras no junto-a-zumbador hacer avanza;
            coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion checa como inicio
        este;
        si frente-libre y derecha-libre entonces inicio
            avanza;
            sur;
            avanza;
            si no junto-a-zumbador entonces inicio
                oeste;
                avanza;
                si frente-libre entonces inicio
                    avanza;
                    si no junto-a-zumbador entonces inicio
                        este;
                        avanza;
                        norte;
                        avanza;
                        take(0);
                    fin sino inicio
                        este;
                        avanza;
                        norte;
                        avanza;
                    fin;
                fin sino inicio
                    norte;
                    avanza;
                    take(0);
                fin;
            fin sino inicio
                oeste;
                avanzA;
                norte;
                avanza;
            fin;
        fin sino inicio
            oeste;
            si izquierda-libre y frente-libre entonces inicio
                avanza;
                sur;
                avanza;
                si junto-a-zumbador entonces inicio
                    norte;
                    avanza;
                    este;
                    avanza;
                fin sino inicio
                    take(0);
                fin;
            fin sino inicio
                take(0);
            fin;
        fin;
    fin;

    define-nueva-instruccion buscar como inicio
        si junto-a-zumbador entonces inicio
            checa;
            mientras junto-a-zumbador hacer coge-zumbador;
            oeste;
            si frente-libre y izquierda-libre entonces inicio
                avanza;
                sur;
                avanza;
                buscar;
                norte;
                avanza;
                este;
                avanza;
            fin;
            este;
            si frente-libre y derecha-libre entonces inicio
                avanza;
                sur;
                avanza;
                buscar;
                norte;
                avanza;
                oeste;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion may(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            may(sucede(n));
        fin sino inicio
            este;
            avanza;
            si si-es-cero(n) entonces inicio
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                    oeste;
                    avanza;
                    deja-zumbador;
                    este;
                    avanza;
                fin;
            fin;
            repetir n veces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    oeste;
                    avanza;
                    deja-zumbador;
                    este;
                    avanza;
                fin;
            fin;
            mientras junto-a-zumbador hacer coge-zumbador;
            sur;
            avanza;
            este;
            avanza;
        fin;
    fin;

    define-nueva-instruccion ele(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ele(sucede(n));
        fin sino inicio
            repetir n veces deja-zumbador;
            oeste;
            avanza;
            repetir n veces deja-zumbador;
            avanza;
            sur;
            mientras no junto-a-zumbador hacer avanza;
            coge-zumbador;
            este;
            mientras no junto-a-zumbador hacer avanza;
            coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion llevar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            llevar(sucede(n));
        fin sino inicio
            norte;
            deja-zumbador;
            mientras frente-libre hacer avanza;
            este;
            repetir 2 veces avanza;
            sur;
            avanza;
            repetir n veces deja-zumbador;
            oeste;
            repetir 2 veces avanza;
            sur;
            mientras no junto-a-zumbador hacer avanza;
            este;
            coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion rep como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            rep;
            deja-zumbador;
        fin sino inicio
            sur;
            mientras no junto-a-zumbador hacer avanza;
            coge-zumbador;
        fin;
    fin;



    inicia-ejecucion
        llevar(0);
        mientras frente-libre hacer inicio
            mientras izquierda-libre y frente-libre hacer avanza;
            si izquierda-bloqueada entonces inicio
                avanza;
                sur;
                avanza;
                buscar;
                norte;
                avanza;
                oeste;
                deja-zumbador;
                mientras frente-libre hacer avanza;
                norte;
                deja-zumbador;
                mientras frente-libre hacer avanza;
                este;
                avanza;
                sur;
                avanza;
                si junto-a-zumbador entonces inicio
                    mientras junto-a-zumbador hacer coge-zumbador;
                    norte;
                    avanza;
                    mientras junto-a-zumbador hacer coge-zumbador;
                    sur;
                    avanza;
                    este;
                    avanza;
                fin sino inicio
                    norte;
                    avanza;
                    oeste;
                    avanza;
                    may(0);
                fin;
                ele(0);
                repetir 2 veces avanza;
            fin;
        fin;
        oeste;
        mientras frente-libre hacer avanza;
        norte;
        deja-zumbador;
        mientras frente-libre hacer avanza;
        rep;
        apagate;
    termina-ejecucion
finalizar-programa
