iniciar-programa
define-nueva-instruccion vuelta como repetir 2 veces gira-izquierda;
define-nueva-instruccion avanzar como mientras frente-libre hacer avanza;
define-nueva-instruccion eskina como inicio
    mientras no-orientado-al-oeste hacer gira-izquierda;
    avanzar;
    mientras no-orientado-al-sur hacer gira-izquierda;
    avanzar;
    vuelta;
fin;
define-nueva-instruccion junta como inicio
    gira-izquierda;
    mientras frente-libre hacer inicio
        avanza;
    fin;
    vuelta;
    mientras frente-libre hacer inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        avanza;
    fin;
    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
    gira-izquierda;
fin;
define-nueva-instruccion zapatos como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        zapatos;
        si orientado-al-este y frente-libre entonces inicio
            avanza;
        fin sino inicio
            si frente-bloqueado y orientado-al-este entonces inicio
                gira-izquierda;
                avanza;
                gira-izquierda;
                avanzar;
                vuelta;
            fin sino inicio
                si frente-bloqueado y orientado-al-oeste entonces vuelta;
            fin;
        fin;
    fin sino inicio
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si junto-a-zumbador entonces inicio
            zapatos;
            si no-junto-a-zumbador entonces deja-zumbador;
            eskina;
            gira-izquierda;
        fin sino inicio
            eskina;
            gira-izquierda;
        fin;
    fin;
fin;
define-nueva-instruccion camina como inicio
    si frente-libre entonces inicio
        avanza;
    fin sino inicio
        gira-izquierda;
        si frente-libre entonces inicio
        avanza;
        gira-izquierda;
        avanzar;
        vuelta;
        fin;
    fin;
fin;
define-nueva-instruccion pares(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        pares(sucede(n));
    fin sino inicio
        camina;
        si orientado-al-este entonces inicio
            pares(n);
        fin sino inicio
            eskina;
            repetir n veces inicio
                deja-zumbador;
            fin;
        fin;
    fin;
fin;
    inicia-ejecucion
    eskina;
    repetir 3 veces gira-izquierda;
    mientras frente-libre hacer inicio
        junta;
        avanza;
    fin;
    junta;
    eskina;
    repetir 3 veces gira-izquierda;
    mientras no-junto-a-zumbador y frente-libre hacer avanza;
    zapatos;
    si no-junto-a-zumbador entonces deja-zumbador;
    eskina;
    repetir 3 veces gira-izquierda;
    eskina;
    repetir 3 veces gira-izquierda;
    pares(0);
        apagate;
    termina-ejecucion
finalizar-programa
