iniciar-programa
define-nueva-instruccion a como si frente-libre entonces avanza;
define-nueva-instruccion gi como gira-izquierda;
define-nueva-instruccion mv como repetir 2 veces gi;
define-nueva-instruccion gd como repetir 3 veces gi;
define-nueva-instruccion sa como mientras frente-libre hacer a;
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gi;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gi;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gi;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gi;
define-nueva-instruccion poner(x) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        poner(precede(x));
    fin
    sino
    inicio
        repetir x veces deja-zumbador;
    fin;
fin;
define-nueva-instruccion comer(x) como
inicio
    si no si-es-cero (x) entonces
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            comer(precede(x));
        fin
        sino
        inicio
            repetir x veces deja-zumbador;
            norte;
        fin;
    fin
    sino
    inicio
        si no-junto-a-zumbador entonces
        inicio
            norte;
        fin;
    fin;
fin;
define-nueva-instruccion distinto(x) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        distinto(sucede(x));
    fin
    sino
    inicio
        si no si-es-cero (x) entonces
        inicio
            oeste;
            sa;
            mv;
            mientras frente-libre hacer
            inicio
                si junto-a-zumbador entonces
                inicio
                    comer(x);
                    si junto-a-zumbador y orientado-al-este entonces repetir x veces deja-zumbador
                    sino
                    inicio
                        este;
                        si junto-a-zumbador entonces poner(x);
                    fin;
                fin;
                a;
            fin;
            gi;
            a;
            deja-zumbador;
            mv;
            a;
            oeste;
            distinto(0);
        fin
        sino
        inicio
            si frente-libre entonces
            inicio
                a;
                distinto(0);
            fin;
        fin;
    fin;
fin;
define-nueva-instruccion contar(x) como
inicio
    si junto-a-zumbador entonces
    inicio
         mientras junto-a-zumbador hacer coge-zumbador;
         a;
         contar(x);
    fin
    sino
    inicio
        sur;
        sa;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        este;
        si frente-libre entonces
        inicio
            a;
            norte;
            contar(0);
        fin;
    fin;
fin;
    inicia-ejecucion
    sur;
    sa;
    oeste;
    sa;
    norte;
    contar(0);
    mv;
    distinto(0);
    este;
    sa;
    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
    gi;
    a;
    mientras junto-a-zumbador hacer coge-zumbador;
    sur;
    a;
    oeste;
    sa;
    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
           apagate;
    termina-ejecucion
finalizar-programa
