iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion recoge como inicio
      mientras junto-a-zumbador hacer inicio
        mientras junto-a-zumbador hacer inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            si frente-libre entonces avanza;
        fin;
        sur;
        mientras frente-libre hacer avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        este;
        si frente-libre entonces inicio
            avanza;
            norte;
        fin sino inicio
            norte;
            avanza;
        fin;
      fin;
    fin;
    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
        este;
    fin;
    define-nueva-instruccion camina como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            oeste;
            mientras frente-libre hacer avanza;
            norte;
            avanza;
            este;
        fin;
    fin;
    define-nueva-instruccion res como inicio
       mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
       norte;
       repetir 5 veces avanza;
       oeste;
       repetir 5 veces inicio
           mientras frente-libre hacer inicio
               si junto-a-zumbador entonces coge-zumbador;
               avanza;
           fin;
           si junto-a-zumbador entonces coge-zumbador;
           sur;
           avanza;
           mientras frente-libre hacer gira-izquierda;
           repetir 2 veces gira-izquierda;
       fin;
       mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
       apagate;
    fin;
    define-nueva-instruccion busca como inicio
        mientras no-junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        si no-junto-a-zumbador entonces res;
    fin;
    define-nueva-instruccion acomoda(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            acomoda(sucede(n));
        fin sino inicio
            norte;
            avanza;
            oeste;
            mientras frente-libre hacer avanza;
            este;
            repetir precede(n) veces camina;
            deja-zumbador;
            ir11;
            busca;
        fin;
    fin;
    inicia-ejecucion
        ir11;
        norte;
        recoge;
        ir11;
        busca;
        mientras junto-a-zumbador hacer acomoda(0);
        apagate;
    termina-ejecucion
finalizar-programa
