iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
        este;
    fin;

    define-nueva-instruccion recoge como inicio
        norte;
        mientras junto-a-zumbador hacer inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            si frente-libre entonces inicio
                avanza;
            fin;
        fin;
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        este;
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            oeste;
        fin;
    fin;

    define-nueva-instruccion reparte(n) como inicio
        si no si-es-cero(n) entonces inicio
            repetir precede(n) veces inicio
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    norte;
                    avanza;
                    si izquierda-bloqueada entonces inicio
                        este;
                    fin sino inicio
                        oeste;
                    fin;
                fin;
            fin;
            si no junto-a-zumbador entonces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion contar(n) como inicio
        si junto-a-zumbador y orientado-al-oeste entonces inicio
            coge-zumbador;
            contar(sucede(n));
        fin sino inicio
            si frente-libre y orientado-al-oeste entonces inicio
                avanza;
                contar(0);
             fin;
             ir11;
             reparte(n);
        fin;
    fin;

    define-nueva-instruccion respuesta como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            respuesta;
            deja-zumbador;
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                respuesta;
            fin sino inicio
                sur;
                si frente-libre entonces inicio
                    avanza;
                    si izquierda-bloqueada entonces inicio
                        oeste;
                    fin sino inicio
                        si derecha-bloqueada entonces inicio
                            este;
                        fin;
                    fin;
                    respuesta;
                fin sino inicio
                    ir11;
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
        ir11;
        mientras no orientado-al-oeste y junto-a-zumbador hacer inicio
            recoge;
        fin;
        oeste;
        si frente-libre y no junto-a-zumbador entonces avanza;
        mientras no junto-a-zumbador y frente-libre hacer avanza;
        contar(0);
        ir11;
        norte;
        repetir 5 veces avanza;
        este;
        respuesta;
        apagate;
    termina-ejecucion
finalizar-programa
