iniciar-programa
    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;

    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;

    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
    fin;

    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;

    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
    fin;

    define-nueva-instruccion reunir como inicio
        norte;
        mientras (junto-a-zumbador y frente-libre) hacer inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            avanza;
        fin;
        sur;
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
        mientras frente-libre hacer avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        este;
    fin;

    define-nueva-instruccion llega11 como inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
    fin;

    define-nueva-instruccion paso como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            gira(2);
            mientras frente-libre hacer avanza;
            norte;
            avanza;
            gira(3);
        fin;
    fin;

    define-nueva-instruccion cubeta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cubeta(sucede(n));
        fin sino inicio
            llega11;
            norte;
            avanza;
            este;
            repetir precede(n) veces paso;
            si no-junto-a-zumbador entonces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion recoge como inicio
        este;
        mientras frente-libre hacer inicio
            si junto-a-zumbador entonces coge-zumbador;
            avanza;
        fin;
        si junto-a-zumbador entonces coge-zumbador;
        oeste;
        mientras frente-libre hacer avanza;
        norte;
        avanza;
    fin;

    inicia-ejecucion
        llega11;
        este;
        mientras frente-libre hacer inicio
            reunir;
            avanza;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
        fin;
        reunir;
        llega11;
        este;
        mientras frente-libre hacer inicio
            si junto-a-zumbador entonces cubeta(0);
            llega11;
            este;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
        fin;
        si junto-a-zumbador entonces cubeta(0);
        llega11;
        este;
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        oeste;
        avanza;
        norte;
        avanza;
        repetir 5 veces recoge;
        llega11;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        apagate;
    termina-ejecucion
finalizar-programa
