iniciar-programa
    define-nueva-instruccion gira(z) como inicio
        repetir z veces gira-izquierda;
    fin;
    define-nueva-instruccion p11 como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        gira(3);
    fin;
    define-nueva-instruccion altura como inicio
        mientras junto-a-zumbador hacer inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            si frente-libre y no-junto-a-zumbador entonces avanza;
        fin;
        gira(2);
        mientras frente-libre hacer avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
    fin;
    define-nueva-instruccion talla(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            talla(sucede(n));
        fin;
        si no-junto-a-zumbador entonces inicio
            gira(2);
            mientras frente-libre hacer avanza;
            gira(3);
            avanza;
            gira(3);
            si no si-es-cero(n) entonces repetir precede(n) veces inicio
                si frente-bloqueado entonces inicio
                    gira(2);
                    mientras frente-libre hacer avanza;
                    gira(3);
                    avanza;
                    gira(3);
                fin sino si frente-libre entonces avanza;
            fin;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion diferencia(n) como inicio
        si no-junto-a-zumbador entonces inicio
            mientras frente-libre y no-junto-a-zumbador hacer avanza;
            si frente-bloqueado y no-junto-a-zumbador entonces inicio
                gira(2);
                mientras frente-libre hacer avanza;
                gira(1);
                si frente-libre entonces inicio
                    avanza;
                    gira(1);
                fin;
            fin;
        fin;
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            diferencia(sucede(n));
        fin sino si derecha-libre entonces diferencia(n);
        si no-junto-a-zumbador y derecha-bloqueada entonces inicio
            repetir n veces deja-zumbador;
            apagate;
        fin;
    fin;
inicia-ejecucion
    p11;
    mientras junto-a-zumbador y frente-libre hacer inicio
        altura;
        gira(1);
        si frente-libre entonces inicio
            avanza;
            gira(1);
        fin;
    fin;
    mientras no-orientado-al-oeste hacer gira-izquierda;
    mientras frente-libre hacer avanza;
    gira(2);
    mientras frente-libre hacer inicio
        talla(0);
        p11;
        gira(3);
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
    fin;
    gira(2);
    mientras frente-libre hacer avanza;
    gira(3);
    repetir 6 veces si frente-libre entonces avanza;
    gira(3);
    diferencia(0);
        apagate;
    termina-ejecucion
finalizar-programa
