iniciar-programa

define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no orientado-al-sur hacer  gira-izquierda;
define-nueva-instruccion este como  mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion come(n) como inicio
    repetir n veces inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            norte;
            avanza;
            deja-zumbador;
            sur;
            avanza;
        fin sino inicio
            este;
            sal-de-instruccion;
        fin;
    fin;
fin;

define-nueva-instruccion es_la_talla(n) como inicio
    come(n);
    si orientado-al-este o junto-a-zumbador entonces inicio
        norte;
        avanza;
        mientras junto-a-zumbador hacer inicio
            coge-zumbador;
            sur;
            avanza;
            deja-zumbador;
            norte;
            avanza;
        fin;
        sur;
        avanza;
    fin;
    oeste;
fin;

define-nueva-instruccion talla(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        talla(sucede(n));
    fin sino inicio
        mientras no orientado-al-sur hacer inicio
            mientras no junto-a-zumbador y frente-libre hacer avanza;
            si junto-a-zumbador entonces inicio
                es_la_talla(n);
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    sur;
                fin;
            fin sino inicio
                sur;
            fin;
        fin;
    fin;
fin;

define-nueva-instruccion compara(x) como inicio
    si si-es-cero(x) entonces inicio
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            deja-zumbador;
        fin;
    fin sino inicio
        repetir x veces avanza;
        oeste;
        si junto-a-zumbador entonces inicio
            talla(0);
            este;
            compara(precede(x));
            deja-zumbador;
        fin sino inicio
            repetir x veces avanza;
            este;
            compara(precede(x));
        fin;
    fin;
fin;

define-nueva-instruccion largo(x) como inicio
    si frente-libre entonces inicio
        avanza;
        largo(sucede(x));
    fin sino inicio
        este;
        compara(x);
    fin;
fin;

define-nueva-instruccion junta como inicio
    mientras no orientado-al-sur hacer inicio
        norte;
        mientras junto-a-zumbador y frente-libre hacer avanza;
        sur;
        si no junto-a-zumbador y frente-libre entonces avanza;
        mientras junto-a-zumbador hacer inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            si frente-libre entonces avanza;
        fin;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        si derecha-libre entonces inicio
            oeste;
            si frente-libre entonces avanza;
        fin;
    fin;
    si junto-a-zumbador entonces inicio
    este;
    mientras junto-a-zumbador y frente-libre hacer avanza;
    oeste;
    si no junto-a-zumbador y frente-libre entonces avanza;
    largo(0);
    fin;
fin;

    inicia-ejecucion
    sur;
    mientras frente-libre hacer avanza;
    oeste;
    mientras frente-libre hacer avanza;
    este;
    mientras junto-a-zumbador y frente-libre hacer avanza;
    oeste;
    si no junto-a-zumbador y frente-libre entonces avanza;
    junta;
        apagate;
    termina-ejecucion
finalizar-programa
