iniciar-programa
    define-nueva-instruccion gira(n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira(1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira(1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira(1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira(1);
    fin;
    define-nueva-instruccion orienta como inicio
        oeste;
        mientras frente-libre hacer
            avanza;
        sur;
        mientras frente-libre hacer
        avanza;
        este;
    fin;
    define-nueva-instruccion proceso como inicio
        mientras junto-a-zumbador hacer inicio
            norte;
            mientras junto-a-zumbador hacer inicio
                mientras junto-a-zumbador hacer
                    coge-zumbador;
                si frente-libre entonces
                    avanza;
            fin;
            sur;
            mientras frente-libre hacer
                avanza;
            mientras algun-zumbador-en-la-mochila hacer
                deja-zumbador;
            este;
            si frente-libre entonces inicio
                avanza;
            fin
            sino inicio
                sal-de-instruccion;
            fin;
        fin;
    fin;
    define-nueva-instruccion cuenta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(n));
        fin
        sino inicio
            orienta;
            norte;
            avanza;
            este;
            repetir precede(n) veces inicio
                si frente-libre entonces inicio
                   avanza;
                fin
                sino inicio
                   norte;
                   avanza;
                   oeste;
                   mientras frente-libre hacer
                      avanza;
                   este;
                fin;
            fin;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion cubetazo como inicio
        orienta;
        mientras no-junto-a-zumbador y frente-libre hacer
            avanza;
        si junto-a-zumbador entonces inicio
            cuenta(0);
            orienta;
            cubetazo;
        fin;
    fin;
    define-nueva-instruccion contar(n) como inicio
        mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer
                coge-zumbador;
            contar(sucede(n));
        fin
        sino inicio
           norte;
           si frente-libre entonces inicio
              avanza;
              oeste;
              mientras frente-libre hacer
                 avanza;
              este;
              contar(n);
           fin
           sino inicio
               orienta;
               repetir n veces
                   deja-zumbador;
               norte;
               apagate;
           fin;
        fin;
    fin;
    define-nueva-instruccion termina como inicio
        norte;
        avanza;
        este;
        contar(0);
    fin;
    inicia-ejecucion
        orienta;
        proceso;
        cubetazo;
        orienta;
        termina;
        apagate;
    termina-ejecucion
finalizar-programa
