iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion ir11 como inicio
    sur;
    mientras frente-libre hacer inicio
        avanzA;
    fin;
    oeste;
    mientras frente-libre hacer inicio
        avanzA;
    fin;
fin;

define-nueva-instruccion talla como inicio
    mientras junto-a-zumbador hacer inicio
        coge-zumbador;
        si frente-libre y no-junto-a-zumbador entonces inicio
            avanzA;
        fin;
    fin;
    sur;
    mientras frente-libre hacer inicio
        avanzA;
    fin;
    mientras algun-zumbador-en-la-mochila hacer inicio
       deja-zumbador;
    fin;
    este;
    si frente-libre entonces inicio
        avanzA;
        norte;
        si junto-a-zumbador entonces inicio
            talla;
        fin;
    fin;
fin;

define-nueva-instruccion colocar como inicio
    oeste;
    mientras frente-libre hacer inicio
        avanzA;
    fin;
    norte;
    avanza;
    este;
fin;
define-nueva-instruccion marcar(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        marcar(sucede(n));
    fin sino inicio
        si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
                marcar(0);
            fin;
        fin;
        ir11;
        este;
        repetir precede(n) veces inicio
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                colocar;
            fin;
        fin;
        deja-zumbador;
    fin;
fin;

define-nueva-instruccion cambiar como inicio
    oeste;
    mientras frente-libre hacer inicio
        avanzA;
    fin;
    sur;
    si frente-libre entonces inicio
        avanzA;
        este;
    fin;
fin;


define-nueva-instruccion juntar(n) como inicio
    si junto-a-zumbador entonces inicio
        mientras junto-a-zumbador hacer inicio
            coge-zumbador;
        fin;
        juntar(sucede(n));
    fin sino inicio
        mientras no junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        si frente-bloqueado y no-junto-a-zumbador entonces inicio
            cambiar;
        fin;
    fin;
    si no-orientado-al-sur entonces inicio
            juntar(0);
    fin;
    repetir n veces inicio
        deja-zumbador;
    fin;    
fin;
    inicia-ejecucion
    ir11;
    norte;
    talla;
    ir11;
    este;
    marcar(0);
    norte;
    ir11;
    norte;
    repetir 4 veces inicio
        avanza;
    fin;
    este;
    juntar(0);
        apagate;
    termina-ejecucion
finalizar-programa
