iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion amontonar como inicio
        norte;
        mientras no orientado-al-este hacer inicio
            mientras junto-a-zumbador hacer inicio
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                fin;
                si frente-libre entonces inicio
                    avanza;
                fin;
            fin;
            sur;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            mientras algun-zumbador-en-la-mochila hacer inicio
                deja-zumbador;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    norte;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion avanzar como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                gira-izquierda;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                repetir 2 veces gira-izquierdA;
            fin;
        fin;
    fin;

    define-nueva-instruccion ir11 como inicio
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
    fin;

    define-nueva-instruccion recoger(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoger(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                recoger(0);
            fin;
            si no si-es-cero(n) entonces inicio
                ir11;
                repetir precede(n) veces inicio
                    avanzar;
                fin;
                si no junto-a-zumbador entonces inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion ubicar como inicio
        norte;
        repetir 4 veces inicio
            avanza;
        fin;       
        este;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        oeste;
    fin;

    define-nueva-instruccion tallas(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            tallas(sucede(n));
        fin sino inicio
            avanzar;
            si no orientado-al-sur entonces inicio
                tallas(0);
            fin;
            si si-es-cero(precede(n)) entonces inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    inicia-ejecucion
        ir11;
        amontonar;
        oeste;
        recoger(0);
        ubicar;
        tallas(0);
        apagate;
    termina-ejecucion
finalizar-programa
