iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion compara(x) como inicio
        si no(si-es-cero(x)) entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                compara(precede(x));
                si orientado-al-oeste entonces deja-zumbador;
            fin;
        fin sino inicio
            si no-junto-a-zumbador entonces gira(1);
        fin;
    fin;

    define-nueva-instruccion cuenta(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(x));
        fin sino inicio
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            mientras junto-a-zumbador y frente-libre hacer inicio
                compara(x);
                mientras no-orientado-al-oeste hacer gira-izquierda;
                si junto-a-zumbador entonces avanza;
                mientras no-junto-a-zumbador y frente-libre hacer avanza;
            fin;
            compara(x);
            mientras no-orientado-al-norte hacer gira-izquierda;
            avanza;
            deja-zumbador;
            gira(2);
            avanza;
        fin;
    fin;

    define-nueva-instruccion bajar_beepers(x) como inicio
        mientras junto-a-zumbador y frente-libre hacer avanza;
        gira(2);
        mientras frente-libre hacer inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            avanza;
        fin;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        si derecha-libre entonces inicio
            gira(3);
            avanza;
            gira(3);
            bajar_beepers(sucede(x));
            mientras no-orientado-al-este hacer gira-izquierda;
            repetir sucede(x) veces avanza;
            gira(2);
            mientras frente-libre y no-junto-a-zumbador hacer avanza;
            si junto-a-zumbador entonces inicio
                cuenta(0);
            fin;
        fin;
    fin;

    define-nueva-instruccion ir_inicio como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(1);
        mientras frente-libre hacer avanza;
        gira(1);
    fin;

    define-nueva-instruccion resultado como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            resultado;
            deja-zumbador;
        fin sino inicio
            avanza;
        fin;
    fin;

    inicia-ejecucion
        ir_inicio;
        mientras junto-a-zumbador y frente-libre hacer avanza;
        gira(2);
        si no-junto-a-zumbador y frente-libre entonces avanza;
        gira(3);
        bajar_beepers(0);
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            mientras no-orientado-al-norte hacer gira-izquierda;
            avanza;
            deja-zumbador;
            gira(2);
            avanza;
        fin;
        mientras no-orientado-al-norte hacer gira-izquierda;
        avanza;
        gira(2);
        resultado;
        apagate;
    termina-ejecucion
finalizar-programa
