iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion avanzar como mientras frente-libre hacer avanza;
define-nueva-instruccion nada(n) como inicio

fin;
define-nueva-instruccion quita(n) como inicio
    si no si-es-cero(n) entonces inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            quita(precede(n));
            si orientado-al-sur entonces inicio
                deja-zumbador;
            fin;
            nada(sucede(n));
        fin sino inicio
            oeste;
            avanza;
            repetir n veces deja-zumbador;
            este;
            avanza;
            sur;
        fin;
    fin;
fin;
define-nueva-instruccion divide(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        divide(sucede(n));
    fin sino inicio
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        repetir n veces coge-zumbador;
        norte;
        mientras orientado-al-norte hacer inicio
            quita(n);
            si orientado-al-norte entonces inicio
                avanza;
                deja-zumbador;
                sur;
                avanza;
                norte;
            fin;
        fin;
        fin;
fin;
define-nueva-instruccion menor(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        menor(sucede(n));
    fin sino inicio
        avanza;
        repetir n veces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
            fin sino inicio
                sur;
            fin;
        fin;
        si orientado-al-sur entonces inicio
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            repetir n veces coge-zumbador;
            divide(0);
        fin sino inicio
            si no-junto-a-zumbador entonces inicio
                avanza;
                repetir n veces deja-zumbador;
                apagate;
            fin sino inicio
                repetir n veces deja-zumbador;
                norte;
                mientras orientado-al-norte hacer inicio
                    quita(n);
                    si orientado-al-norte entonces inicio
                        avanza;
                        deja-zumbador;
                        sur;
                        avanza;
                        norte;
                    fin;
                fin;
            fin;
        fin;
    fin;
fin;
define-nueva-instruccion lleva como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        lleva;
        deja-zumbador;
    fin sino inicio
        este;
        avanza;
        avanza;
    fin;
fin;
    inicia-ejecucion
    sur;
    avanzar;
    oeste;
    avanzar;
    este;
    menor(0);
    mientras junto-a-zumbador hacer inicio
        norte;
        avanza;
        mientras junto-a-zumbador hacer coge-zumbador;
        sur;
        avanza;
        oeste;
        avanza;
        norte;
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        sur;
        avanza;
        este;
        menor(0);
    fin;
    si orientado-al-sur y no-junto-a-zumbador entonces inicio
        oeste;
        avanza;
        lleva;
    fin;
        apagate;
    termina-ejecucion
finalizar-programa
