iniciar-programa
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion ubicarse como inicio
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
    fin;
    define-nueva-instruccion ordena(n) como inicio
        si junto-a-zumbador entonces inicio
            si no si-es-cero(n) entonces inicio
                coge-zumbador;
                ordena(precede(n));
                deja-zumbador;
                avanza;
                deja-zumbador;
                ubicarse;
            fin;
        fin sino inicio
            repetir n veces inicio
                deja-zumbador;
            fin;
        fin;
        ubicarse;
    fin;
    define-nueva-instruccion cuenta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(n));
        fin sino inicio
            avanza;
            ordena(n);
        fin;
    fin;
    define-prototipo-instruccion cuenta-2(n);
    define-nueva-instruccion saca-residuo(n) como inicio
        repetir n veces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
            fin sino inicio
                norte;
                avanza;
                deja-zumbador;
                sur;
                avanza;
            fin;
        fin;
        si junto-a-zumbador entonces inicio
            saca-residuo(n);
        fin;
        si orientado-al-sur entonces inicio
            norte;
            avanza;
            oeste;
            repetir n veces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin sino inicio
                    avanza;
                    deja-zumbador;
                    este;
                    avanza;
                    oeste;
                fin;
            fin;
            repetir n veces inicio
                deja-zumbador;
            fin;
            avanza;
            este;
            cuenta-2(0);
        fin;
        si no-orientado-al-sur y no-junto-a-zumbador entonces inicio
            ubicarse;
            avanza;
            avanza;
            repetir n veces inicio
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion cuenta-2(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta-2(sucede(n));
        fin sino inicio
            avanza;
            saca-residuo(n);
        fin;
    fin;
    inicia-ejecucion
        ubicarse;
        cuenta(0);
        cuenta-2(0);
        apagate;
    termina-ejecucion
finalizar-programa
