iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion dejaResiduo como inicio
        norte;
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        sur;
        avanza;
    fin;

    define-nueva-instruccion quita(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            quita(sucede(n));
        fin sino inicio
            repetir n veces inicio
                deja-zumbador;
            fin;
            este;
            avanza;
            repetir n veces inicio
                coge-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion cambia(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cambia(sucede(n));
        fin sino inicio
            avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
            repetir n veces inicio
                deja-zumbador;
            fin;
            oeste;
            avanza;
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            este;
        fin;
    fin;

    define-nueva-instruccion ordena(n) como inicio
        si junto-a-zumbador y no si-es-cero(n) entonces inicio
            repetir precede(n) veces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin;
            fin;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si no junto-a-zumbador entonces inicio
                    mientras junto-a-zumbador hacer coge-zumbador;
                    este;
                    avanza;
                    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                    apagate;
                fin sino inicio
                    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                    oeste;
                    mientras frente-libre hacer avanza;
                    quita(0);
                    dejaResiduo;
                fin;
            fin sino inicio
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                oeste;
                avanza;
                este;
                cambia(0);
                quita(0);
                dejaResiduo
            fin;
        fin;
    fin;

    define-nueva-instruccion galleta(n) como inicio
         si junto-a-zumbador entonces inicio
             coge-zumbador;
             galleta(sucede(n));
         fin sino inicio
             repetir n veces inicio
                 deja-zumbador;
             fin;
             este;
             avanza;
             ordena(n);
         fin;
     fin;

    inicia-ejecucion
        sur;
        mientras frente-libre hacer avanza;
        este;
        mientras no orientado-al-oeste hacer inicio
            oeste;
            mientras frente-libre hacer avanza;
            este;
            galleta(0);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
