iniciar-programa
     define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion ir11 como inicio
        oeste;
        corre;
        sur;
        corre;
    fin;
    define-nueva-instruccion menor(n) como inicio
        si no si-es-cero(n) y junto-a-zumbador entonces inicio
            coge-zumbador;
            menor(precede(n));
            deja-zumbador;
        fin sino inicio
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion ordena(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ordena(sucede(n));
        fin sino inicio
            este;
            avanza;
            menor(n);
            oeste;
            avanza;
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion resta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            resta(sucede(n));
        fin sino inicio
            oeste;
            avanza;
            repetir n veces coge-zumbador;
            si junto-a-zumbador entonces inicio
                este;
                avanza;
                repetir n veces deja-zumbador;
                oeste;
                avanza;
                norte;
                avanza;
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                sur;
                avanza;
            fin sino inicio
                este;
                repetir 2 veces avanza;
                repetir n veces deja-zumbador;
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion mcm como inicio
        mientras junto-a-zumbador hacer inicio
            ordena(0);
            este;
            avanza;
            resta(0);
        fin;
    fin;
    inicia-ejecucion
        ir11;
        mcm;
        apagate;
    termina-ejecucion
finalizar-programa
