iniciar-programa

    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;

    define-nueva-instruccion compara(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            compara(sucede(n));
        fin sino inicio
            avanza;
            repetir n veces si junto-a-zumbador entonces inicio
                coge-zumbador;
                gira(2);
                avanza;
                deja-zumbador;
                gira(2);
                avanza;
            fin;

            repetir n veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion resta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            resta(sucede(n));
            coge-zumbador;
        fin sino inicio
            repetir n veces deja-zumbador;
            avanza;
        fin;
    fin;

    define-nueva-instruccion regresa como inicio
        gira(2);
        avanza;
        gira(2);
    fin;

    define-nueva-instruccion arrastra como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            arrastra;
            deja-zumbador;
        fin sino inicio
            avanza;
        fin;
    fin;

    inicia-ejecucion
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-este hacer gira-izquierda;
        mientras junto-a-zumbador hacer inicio
            compara(0);
            regresa;
            resta(0);
            regresa;
        fin;
        avanza;
        arrastra;
        apagate;
    termina-ejecucion
finalizar-programa
