iniciar-programa
    define-nueva-instruccion gira(n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira(1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira(1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira(1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira(1);
    fin;
    define-nueva-instruccion orienta como inicio
        oeste;
        mientras frente-libre hacer
            avanza;
        sur;
        mientras frente-libre hacer
            avanza;
        este;
    fin;
    define-nueva-instruccion coge(n) como inicio
        si junto-a-zumbador y no si-es-cero(n) entonces inicio
            coge-zumbador;
            coge(precede(n));
            deja-zumbador;
        fin
        sino inicio
            si si-es-cero(n) entonces inicio
                norte;
            fin
            sino inicio
                sur;
            fin;
        fin;
    fin;
    define-nueva-instruccion pasa(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            pasa(sucede(n));
        fin
        sino inicio
            orienta;
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion ordena(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ordena(sucede(n));
        fin
        sino inicio
            este;
            avanza;
            coge(n);
            si orientado-al-norte entonces inicio
                orienta;
                repetir n veces
                    deja-zumbador;
            fin
            sino inicio
                pasa(0);
                avanza;
                repetir n veces
                    deja-zumbador;
                orienta;
            fin;
        fin;
    fin;
    define-nueva-instruccion residuo(n) como inicio
        si junto-a-zumbador y no (si-es-cero(n)) entonces inicio
            coge-zumbador;
            residuo(precede(n));
            si orientado-al-norte entonces
                deja-zumbador;
        fin
        sino inicio
            si no-junto-a-zumbador y si-es-cero(n) entonces inicio
               sur;
            fin
            sino inicio
                si junto-a-zumbador y si-es-cero(n) entonces inicio
                    este;
                fin
                sino inicio
                    si no-junto-a-zumbador y no si-es-cero(n) entonces inicio
                        norte;
                    fin;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion MCD(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            MCD(sucede(n));
        fin
        sino inicio
            repetir n veces
                deja-zumbador;
            avanza;
            mientras no-orientado-al-norte hacer inicio
               residuo(n);
               si orientado-al-sur entonces inicio
                   este;
                   avanza;
                   repetir n veces
                       deja-zumbador;
                   apagate;
               fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion proceso como inicio
        orienta;
        ordena(0);
        MCD(0);
        si orientado-al-norte entonces
            proceso;
    fin;
    inicia-ejecucion
        proceso;
        apagate;
    termina-ejecucion
finalizar-programa