iniciar-programa
    define-nueva-instruccion gira(z) como inicio
        repetir z veces gira-izquierda;
    fin;
    define-nueva-instruccion mayor(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mayor(sucede(n));
        fin;
        si no-junto-a-zumbador entonces inicio
            repetir n veces deja-zumbador;
            avanza;
            repetir n veces inicio
                si junto-a-zumbador entonces coge-zumbador sino inicio
                    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                    gira(2);
                    sal-de-instruccion;
                fin;
            fin;
            si junto-a-zumbador entonces inicio
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                sal-de-instruccion;
            fin;
            si no-junto-a-zumbador entonces inicio
                gira(1);
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                sal-de-instruccion;
            fin;
        fin;
    fin;
    define-nueva-instruccion mover(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mover(sucede(n));
        fin;
        si no-junto-a-zumbador entonces inicio
            avanza;
            repetir n veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion acomodar como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            coge-zumbador;
            acomodar;
            si frente-libre entonces inicio
                avanza;
                gira(2);
                mover(0);
                gira(2);
                avanza;
            fin;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion resta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            resta(sucede(n));
        fin;
        si no-junto-a-zumbador entonces inicio
            repetir n veces deja-zumbador;
            avanza;
            repetir n veces coge-zumbador;
            avanza;
            si junto-a-zumbador entonces inicio
                mover(0);
                gira(2);
                avanza;
                gira(2);
            fin;
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        fin;
    fin;
inicia-ejecucion
    mientras no-orientado-al-sur hacer gira-izquierda;
    mientras frente-libre hacer avanza;
    gira(3);
    mientras frente-libre hacer avanza;
    gira(2);
    avanza;
    mientras junto-a-zumbador hacer inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(2);
        mayor(0);
        si orientado-al-oeste entonces acomodar sino inicio
            mientras no-orientado-al-oeste hacer gira-izquierda;
            mientras frente-libre hacer avanza;
            gira(2);
        fin;
        si frente-bloqueado y orientado-al-oeste entonces gira(2);
        resta(0);
        gira(2);
        avanza;
    fin;
        apagate;
    termina-ejecucion
finalizar-programa
