iniciar-programa
define-nueva-instruccion g(n) como
    repetir n veces gira-izquierda;
define-nueva-instruccion lleva(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        lleva(sucede(n));
    fin
    sino
    inicio
        avanza;
        repetir n veces deja-zumbador;
        g(2);
        avanza;
        g(2);
    fin;
fin;
define-nueva-instruccion mcd(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        mcd(sucede(n));
    fin
    sino
    inicio
        avanza;
        mientras orientado-al-oeste y junto-a-zumbador hacer
        repetir n veces
            si junto-a-zumbador entonces
                coge-zumbador
                sino
                inicio
                   g(2);
                   repetir precede(n) veces deja-zumbador;
               fin;
        si junto-a-zumbador entonces
        inicio
            lleva(0);
            repetir n veces deja-zumbador;
            avanza;
            g(2);
        fin
        sino
        inicio
            mientras no-orientado-al-este hacer gira-izquierda;
            repetir 2 veces avanza;
            repetir n veces deja-zumbador;
            apagate;
        fin;
    fin;
fin;
    inicia-ejecucion
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        g(3);
        mientras frente-libre hacer avanza;
        g(2);
        avanza;
        g(2);
        coge-zumbador;
        si junto-a-zumbador entonces
            deja-zumbador
        sino
        inicio
            deja-zumbador;
            avanza;
            si junto-a-zumbador entonces coge-zumbador;
            si no-junto-a-zumbador entonces apagate;
            deja-zumbador;
            g(2);
            avanza;
            g(2);
        fin;
        mientras frente-libre o frente-bloqueado hacer
            mcd(0);
        apagate;
    termina-ejecucion
finalizar-programa
