iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;
    define-nueva-instruccion regresa como inicio
        gira(2);
        avanza;
    fin;

    define-nueva-instruccion mover como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mover;
            deja-zumbador;
        fin sino inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion vaciarMochila como inicio
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        regresa;
    fin;

    define-nueva-instruccion comer(x) como inicio
        repetir x veces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
            fin sino inicio   (*menor*)
                regresa;
                repetir x veces deja-zumbador;
                regresa;
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                gira(2);
                sal-de-instruccion;
            fin;
        fin;
        si junto-a-zumbador entonces inicio   (*mayor*)
            gira(2);
            mover;
            repetir x veces deja-zumbador;
            regresa;
            repetir x veces deja-zumbador;
            gira(2);
        fin sino inicio   (*iguales*)
            avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
            repetir x veces deja-zumbador;
            apagate;
        fin;
    fin;

    define-nueva-instruccion comparar(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            comparar(sucede(x));
        fin sino inicio
            avanza;
            comer(x);
        fin;
    fin;

    define-nueva-instruccion restar(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            restar(sucede(x));
        fin sino inicio
            avanza;
            repetir x veces coge-zumbador;
            regresa;
            repetir x veces deja-zumbador;
            vaciarMochila;
            avanza;
            gira(2);
        fin;
    fin;

    inicia-ejecucion
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        gira(2);
        mientras junto-a-zumbador hacer inicio
            comparar(0);
            restar(0);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
