iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion orienta como inicio
        sur;
        mientras frente-libre hacer
            avanza;
        oeste;
        mientras frente-libre hacer
            avanza;
        este;
    fin;
    define-nueva-instruccion checa (n) como inicio
        si no si-es-cero (n) entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                checa (precede(n));
                deja-zumbador;
            fin
            sino inicio
                norte;
            fin;
        fin;
    fin;
    define-nueva-instruccion cambio (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cambio (sucede(n));
        fin
        sino inicio
            oeste;
            avanza;
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
                este;
                avanza;
                deja-zumbador;
                oeste;
                avanza;
            fin;
            repetir n veces
                deja-zumbador;
            este;
        fin;
    fin;
    define-nueva-instruccion menor (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            menor (sucede(n));
        fin
        sino inicio
            repetir n veces
                deja-zumbador;
            avanza;
            checa (n);
            si orientado-al-norte entonces inicio
                cambio (0);
            fin
            sino inicio
                oeste;
                avanza;
                este;
            fin;
        fin;
    fin;
    define-nueva-instruccion residuo (n) como inicio
        si no si-es-cero (n) entonces inicio
            si junto-a-zumbador y orientado-al-este entonces inicio
                coge-zumbador;
                residuo (precede(n));
                deja-zumbador;
            fin
            sino inicio
                norte;
                residuo (precede(n));
            fin;
        fin;
    fin;
    define-nueva-instruccion resultado (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            resultado (sucede(n));
        fin
        sino inicio
            este;
            avanza;
            avanza;
            repetir n veces
                deja-zumbador;
            apagate;
        fin;
    fin;
    define-nueva-instruccion divide (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            divide (sucede(n));
        fin
        sino inicio
            repetir n veces
                deja-zumbador;
            avanza;
            mientras junto-a-zumbador y no-orientado-al-norte hacer inicio
                residuo (n);
                si orientado-al-este entonces inicio
                    repetir n veces
                        coge-zumbador;
                fin;
            fin;
            si no-junto-a-zumbador entonces inicio
                oeste;
                avanza;
                resultado (0);
            fin
            sino inicio
                oeste;
                avanza;
                este;
            fin;
        fin;
    fin;
    define-nueva-instruccion galletas como inicio
        orienta;
        mientras frente-libre hacer inicio
            menor (0);
            divide (0);
        fin;
    fin;
    inicia-ejecucion
        galletas;
        apagate;
    termina-ejecucion
finalizar-programa