iniciar-programa
    define-nueva-instruccion gira(n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira(1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira(1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira(1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira(1);
    fin;
    define-nueva-instruccion pared como inicio
        mientras frente-libre y (derecha-libre o izquierda-libre) hacer
            avanza;
        si derecha-bloqueada y izquierda-bloqueada entonces inicio
            gira(2);
            avanza;
            gira(2);
        fin;
    fin;
    define-nueva-instruccion cambia como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        coge-zumbador;
                        oeste;
                        pared;
                        norte;
                        pared;
                        sur;
                    fin
                    sino inicio
                        sur;
                        pared;
                        oeste;
                        pared;
                        este;
                    fin;
                fin
                sino inicio
                    este;
                    pared;
                    sur;
                    pared;
                    norte;
                fin;
            fin
            sino inicio
                norte;
                pared;
                este;
                pared;
                oeste;
            fin;
        fin;
        mientras frente-libre y (derecha-bloqueada y izquierda-libre) hacer
            avanza;
        si izquierda-bloqueada entonces inicio
            gira(2);
            avanza;
            gira(2);
        fin;
        gira(3);
        si frente-libre entonces inicio
           avanza;
           mientras derecha-bloqueada y izquierda-bloqueada hacer
               avanza;
        fin;
    fin;
    define-nueva-instruccion zumbador como inicio
        este;
        mientras frente-libre y (derecha-libre o izquierda-libre) y no-junto-a-zumbador hacer inicio
            avanza;
        fin;
        si derecha-bloqueada y izquierda-bloqueada entonces inicio
            gira(2);
            avanza;
            gira(2);
        fin;
        si junto-a-zumbador entonces inicio
            cambia;
            sal-de-instruccion;
        fin;
        oeste;
        pared;
        sur;
        si frente-libre entonces inicio
            avanza;
            si izquierda-bloqueada entonces inicio
                norte;
                avanza;
                pared;
                apagate;
            fin
            sino inicio
                zumbador;
            fin;
        fin
        sino inicio
            norte;
            pared;
            este;
            pared;
            apagate;
        fin;
    fin;
    define-nueva-instruccion proceso como inicio
        norte;
        pared;
        oeste;
        pared;
        zumbador;
        proceso;
    fin;
    inicia-ejecucion
        proceso;
        apagate;
    termina-ejecucion
finalizar-programa
