iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion checa-sur como inicio
        si izquierda-libre entonces inicio
            avanza;
            si izquierda-libre entonces inicio
                este;
                avanza;
                sur;
                avanza;
                oeste;
            fin sino inicio
                este;
                avanza;
                norte;
            fin;
        fin sino inicio
            norte;
        fin;
    fin;

    define-nueva-instruccion cambia como inicio
        este;
        mientras frente-libre y (derecha-libre o izquierda-libre) hacer inicio
            avanza;
        fin;                  
        oeste;
        si izquierda-bloqueada y derecha-bloqueada entonces inicio
            avanza;
        fin;
        checa-sur;
    fin;

    define-nueva-instruccion revisar como inicio
        mientras orientado-al-oeste hacer inicio
            mientras frente-libre y no junto-a-zumbador y (izquierda-libre o derecha-libre) hacer inicio
                avanza;
            fin;
            si izquierda-bloqueada y derecha-bloqueada o frente-bloqueado y no junto-a-zumbador entonces inicio
                este;
                avanza;
                cambia;
            fin sino inicio
                sur;
            fin;
        fin;
    fin;

    define-nueva-instruccion sup-der como inicio
        este;
        repetir 2 veces inicio
            mientras frente-libre y (derecha-libre o izquierda-libre)hacer inicio
                avanza;
            fin;
            si derecha-bloqueada y izquierda-bloqueada entonces inicio
                repetir 2 veces gira-izquierda;
                avanza;
                repetir 3 veces gira-izquierda;
            fin sino inicio
                 gira-izquierda;
            fin;
        fin;
    fin;

    define-nueva-instruccion arriba como inicio
        norte;
        mientras frente-libre y (derecha-libre o izquierda-libre) hacer inicio
            avanza;
        fin;
        oeste;
        mientras frente-libre y (derecha-libre o izquierda-libre) hacer inicio
            avanza;
        fin;
        este;
        mientras izquierda-bloqueada hacer inicio
            avanza;
        fin;
        norte;
        avanza;
        mientras derecha-bloqueada y izquierda-bloqueada hacer inicio
            avanza;
        fin;
        este;
    fin;

    define-nueva-instruccion derecha como inicio
        norte;
        mientras frente-libre y (derecha-libre o izquierda-libre) hacer inicio
            avanza;
        fin;
        sur;
        si izquierda-bloqueada y derecha-bloqueada entonces inicio
            avanza;
        fin;
        este;
        mientras frente-libre y (derecha-libre o izquierda-libre) hacer inicio
            avanza;
        fin;
        sur;
        mientras izquierda-bloqueada hacer inicio
            avanza;
        fin;
        este;
        avanza;
        mientras derecha-bloqueada y izquierda-bloqueada hacer inicio
            avanza;
        fin;
        este;
    fin;

    define-nueva-instruccion abajo como inicio
        sur;
        mientras frente-libre y (derecha-libre o izquierda-libre) hacer inicio
            avanza;
        fin;
        este;
        mientras frente-libre y (derecha-libre o izquierda-libre) hacer inicio
            avanza;
        fin;
        oeste;
        mientras izquierda-bloqueada hacer inicio
            avanza;
        fin;
        sur;
        avanza;
        mientras derecha-bloqueada y izquierda-bloqueada hacer inicio
            avanza;
        fin;
        este;
    fin;
    define-nueva-instruccion izquierda como inicio
        sur;
        mientras frente-libre y (derecha-libre o izquierda-libre) hacer inicio
            avanza;
        fin;
        norte;
        si izquierda-bloqueada y derecha-bloqueada entonces inicio
            avanza;
        fin;
        oeste;
        mientras frente-libre y (derecha-libre o izquierda-libre) hacer inicio
            avanza;
        fin;
        norte;
        mientras izquierda-bloqueada hacer inicio
            avanza;
        fin;
        oeste;
        avanza;
        mientras derecha-bloqueada y izquierda-bloqueada hacer inicio
            avanza;
        fin;
        este;
    fin;

    define-nueva-instruccion siguiente(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            siguiente(sucede(n));
        fin sino inicio
            si si-es-cero(precede(n)) entonces inicio
                arriba;
            fin;
            si si-es-cero(precede(precede(n))) entonces inicio
                derecha;
            fin;
            si si-es-cero(precede(precede(precede(n)))) entonces inicio
                abajo;
            fin;
            si si-es-cero(precede(precede(precede(precede(n))))) entonces inicio
                izquierda;
            fin;
        fin;
    fin;

    inicia-ejecucion
        este;
        mientras no orientado-al-norte hacer inicio
            sup-der;
            revisar;
            siguiente(0);
        fin;
        mientras frente-libre y (derecha-libre o izquierda-libre) hacer inicio
            avanza;
        fin;
        sur;
        si izquierda-bloqueada y derecha-bloqueada entonces inicio
            avanza;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
