iniciar-programa
    define-nueva-instruccion coge(n) como
        repetir n veces coge-zumbador;

    define-nueva-instruccion deja(n) como
        repetir n veces deja-zumbador;

    define-nueva-instruccion buscaSalida(n) como inicio
        si no-junto-a-zumbador y si-es-cero(n) entonces
            apagate;

        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        coge-zumbador;
                        si junto-a-zumbador entonces inicio
                            deja(4);
                        fin
                        sino inicio
                            deja(5);

                            mientras no-orientado-al-oeste hacer gira-izquierda;
                            si frente-libre entonces inicio
                                avanza;
                                buscaSalida(n);
                                mientras no-orientado-al-este hacer gira-izquierda;
                                avanza;
                            fin;

                            si no si-es-cero(n) entonces inicio
                                mientras no-orientado-al-este hacer gira-izquierda;
                                si frente-libre entonces inicio
                                    avanza;
                                    buscaSalida(precede(n));
                                    mientras no-orientado-al-oeste hacer gira-izquierda;
                                    avanza;
                                fin;

                                mientras no-orientado-al-norte hacer gira-izquierda;
                                si frente-libre entonces inicio
                                    avanza;
                                    buscaSalida(precede(n));
                                    mientras no-orientado-al-sur hacer gira-izquierda;
                                    avanza;
                                fin;

                                mientras no-orientado-al-sur hacer gira-izquierda;
                                si frente-libre entonces inicio
                                    avanza;
                                    buscaSalida(precede(n));
                                    mientras no-orientado-al-norte hacer gira-izquierda;
                                    avanza;
                                fin;
                            fin;

                            coge(1);
                        fin;
                    fin
                    sino inicio
                        deja(5);

                        mientras no-orientado-al-sur hacer gira-izquierda;
                        si frente-libre entonces inicio
                            avanza;
                            buscaSalida(n);
                            mientras no-orientado-al-norte hacer gira-izquierda;
                            avanza;
                        fin;

                        si no si-es-cero(n) entonces inicio
                            mientras no-orientado-al-este hacer gira-izquierda;
                            si frente-libre entonces inicio
                                avanza;
                               buscaSalida(precede(n));
                                mientras no-orientado-al-oeste hacer gira-izquierda;
                                avanza;
                            fin;

                            mientras no-orientado-al-norte hacer gira-izquierda;
                            si frente-libre entonces inicio
                                avanza;
                                buscaSalida(precede(n));
                                mientras no-orientado-al-sur hacer gira-izquierda;
                                avanza;
                            fin;

                            mientras no-orientado-al-oeste hacer gira-izquierda;
                            si frente-libre entonces inicio
                                avanza;
                                buscaSalida(precede(n));
                                mientras no-orientado-al-este hacer gira-izquierda;
                                avanza;
                            fin;
                        fin;

                        coge(2);
                    fin;
                fin
                sino inicio
                    deja(5);

                    mientras no-orientado-al-este hacer gira-izquierda;
                    si frente-libre entonces inicio
                        avanza;
                        buscaSalida(n);
                        mientras no-orientado-al-oeste hacer gira-izquierda;
                        avanza;
                    fin;

                    si no si-es-cero(n) entonces inicio
                        mientras no-orientado-al-norte hacer gira-izquierda;
                        si frente-libre entonces inicio
                            avanza;
                            buscaSalida(precede(n));
                            mientras no-orientado-al-sur hacer gira-izquierda;
                            avanza;
                        fin;

                        mientras no-orientado-al-sur hacer gira-izquierda;
                        si frente-libre entonces inicio
                            avanza;
                            buscaSalida(precede(n));
                            mientras no-orientado-al-norte hacer gira-izquierda;
                            avanza;
                        fin;

                        mientras no-orientado-al-oeste hacer gira-izquierda;
                        si frente-libre entonces inicio
                            avanza;
                            buscaSalida(precede(n));
                            mientras no-orientado-al-este hacer gira-izquierda;
                            avanza;
                        fin;
                    fin;

                    coge(3);
                fin;
            fin
            sino inicio
                deja(5);

                mientras no-orientado-al-norte hacer gira-izquierda;
                si frente-libre entonces inicio
                    avanza;
                    buscaSalida(n);
                    mientras no-orientado-al-sur hacer gira-izquierda;
                    avanza;
                fin;

                si no si-es-cero(n) entonces inicio
                    mientras no-orientado-al-este hacer gira-izquierda;
                    si frente-libre entonces inicio
                        avanza;
                        buscaSalida(precede(n));
                        mientras no-orientado-al-oeste hacer gira-izquierda;
                        avanza;
                    fin;

                    mientras no-orientado-al-sur hacer gira-izquierda;
                    si frente-libre entonces inicio
                        avanza;
                        buscaSalida(precede(n));
                        mientras no-orientado-al-norte hacer gira-izquierda;
                        avanza;
                    fin;

                    mientras no-orientado-al-oeste hacer gira-izquierda;
                    si frente-libre entonces inicio
                        avanza;
                        buscaSalida(precede(n));
                        mientras no-orientado-al-este hacer gira-izquierda;
                        avanza;
                    fin;
                fin;

                coge(4);
            fin;
        fin;
    fin;

    define-nueva-instruccion arranca(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            arranca(sucede(n));
        fin
        sino inicio
            avanza;
            buscaSalida(n);
        fin;
    fin;

    inicia-ejecucion
        arranca(0);
        apagate;
    termina-ejecucion
finalizar-programa
