iniciar-programa

define-nueva-instruccion gira(z) como repetir z veces gira-izquierda;

define-nueva-instruccion construir(a) como inicio
    repetir 4 veces inicio
        gira(3);
        mientras junto-a-zumbador y frente-libre hacer avanza;
        si frente-bloqueado entonces inicio
            gira(2);
            repetir precede(a) veces avanza;
            gira(3);
            mientras junto-a-zumbador hacer avanza;
            si no-orientado-al-norte entonces inicio
                gira(2);
                avanza;
                gira(2);
            fin;
        fin sino gira(1);
        mientras izquierda-libre o no-junto-a-zumbador hacer inicio
            si no-junto-a-zumbador entonces deja-zumbador;
            si izquierda-libre entonces inicio
                gira(1);
                avanza;
                gira(3);
                avanza;
            fin;
        fin;
        mientras frente-libre hacer avanza;
        gira(3);
    fin;
fin;

define-nueva-instruccion construir_aux(b) como inicio
    si algun-zumbador-en-la-mochila y izquierda-bloqueada entonces inicio
        mientras junto-a-zumbador y frente-libre hacer avanza;
        si no-junto-a-zumbador entonces inicio
            gira(2);
            mientras frente-libre hacer avanza;
            construir_aux(sucede(b));
        fin sino inicio
            gira(2);
            mientras frente-libre hacer avanza;
            construir_aux(b);
        fin;
    fin sino inicio
        gira(2);
        construir(b);
        si algun-zumbador-en-la-mochila entonces construir_aux(b);
    fin;
fin;

    inicia-ejecucion

        construir_aux(0);

        apagate;
    termina-ejecucion
finalizar-programa
