iniciar-programa
    define-nueva-instruccion gira(m) como repetir m veces gira-izquierda;
    define-nueva-instruccion revisa como inicio
        si frente-libre entonces avanza
        sino inicio
            si orientado-al-norte entonces inicio
                gira(3);
                si frente-libre entonces inicio
                    avanza;
                    gira(3);
                fin;
            fin
            sino inicio
                gira(1);
                si frente-libre entonces inicio
                    avanza;
                    gira(1);
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion almohada como inicio
        si no-orientado-al-este entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                revisa;
                almohada;
            fin
            sino inicio
                revisa;
                almohada;
                si junto-a-zumbador entonces coge-zumbador
                sino inicio
                    mientras no-orientado-al-este hacer gira(1);
                    apagate;
                fin;
            fin;
        fin
        sino inicio
            mientras no-orientado-al-oeste hacer gira(1);
            mientras frente-libre hacer avanza;
            gira(1);
            mientras frente-libre hacer avanza;
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        fin;
    fin;
    inicia-ejecucion
        almohada;
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            mientras no-orientado-al-oeste hacer gira(1);
        fin
        sino mientras no-orientado-al-norte hacer gira(1);
        apagate;
    termina-ejecucion
finalizar-programa
