iniciar-programa
    define-nueva-instruccion vuelta como inicio
        gira-izquierda;
        gira-izquierda;
    fin;

    define-nueva-instruccion gira-derecha como inicio
        vuelta;
        gira-izquierda;
    fin;

    define-nueva-instruccion ir-a-esq-inf-izq como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        mientras frente-libre hacer avanza;
        vuelta;
    fin;

    define-nueva-instruccion avanzar como inicio
        si frente-libre entonces
            avanza
        sino inicio
            si orientado-al-norte entonces inicio
                gira-derecha;
                si frente-libre entonces inicio
                    avanza;
                    gira-derecha;
                fin;
            fin
            sino inicio
                 gira-izquierda;
                 si frente-libre entonces inicio
                     avanza;
                     gira-izquierda;
                 fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion recogeTodosLosZumbadores como inicio
        ir-a-esq-inf-izq;
        mientras no-orientado-al-este hacer inicio
            si junto-a-zumbador entonces coge-zumbador;
            avanzar;
        fin;
    fin;

    define-nueva-instruccion lado-izq-zumbadores como inicio
        ir-a-esq-inf-izq;
        mientras algun-zumbador-en-la-mochila hacer inicio
            deja-zumbador;
            avanzar;
        fin;
    fin;

    define-nueva-instruccion deja-resultado(resultado) como inicio
        ir-a-esq-inf-izq;
        gira-derecha;
        repetir resultado veces gira-izquierda;
        apagate;
    fin;

    define-nueva-instruccion resolver como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            avanzar;
            resolver;
            si orientado-al-este entonces
                deja-resultado(2);
            avanzar;
        fin;
    fin;

    inicia-ejecucion
        recogeTodosLosZumbadores;
        lado-izq-zumbadores;
        ir-a-esq-inf-izq;
        resolver;
        si orientado-al-este entonces
            deja-resultado(1)
        sino
            deja-resultado(0);
    termina-ejecucion
finalizar-programa
