iniciar-programa
define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion ir11 como
  inicio
    sur;
    mientras frente-libre hacer avanza;
    oeste;
    mientras frente-libre hacer avanza;
    norte;
  fin;

define-nueva-instruccion next como
  inicio
    este;
    si frente-libre entonces
      inicio
        avanza;
        si izquierda-bloqueada entonces sur
        sino norte;
      fin
    sino
      inicio
        oeste;
      fin;
  fin;

define-nueva-instruccion contar2(n) como
  inicio
       si no orientado-al-oeste  entonces
        inicio
          si no junto-a-zumbador entonces
            inicio
              si frente-libre entonces avanza sino next;
              contar2(n);
            fin
          sino
            inicio
              coge-zumbador;
              si frente-libre entonces avanza sino next;
              contar2(sucede(n));
            fin;
        fin
       sino
        inicio
        ir11;
        repetir n veces deja-zumbador;
        fin;
  fin;

define-nueva-instruccion contar1(n) como
  inicio
       si no orientado-al-oeste  entonces
        inicio
          si junto-a-zumbador entonces
            inicio
              si frente-libre entonces avanza sino next;
              contar1(n);
            fin
          sino
            inicio
              si frente-libre entonces avanza sino next;
              contar1(sucede(n));
            fin;
        fin
       sino
        inicio
        ir11;
        contar2(0);
        repetir n veces si junto-a-zumbador entonces coge-zumbador sino
          inicio
            este;
            apagate;
          fin;
        si junto-a-zumbador entonces
          inicio
            oeste;
             mientras junto-a-zumbador hacer coge-zumbador;
            apagate;
          fin
        sino
          inicio
            norte;
            apagate;
          fin;
        fin;
  fin;
    inicia-ejecucion
         contar1(0);

        apagate;
    termina-ejecucion
finalizar-programa
