iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion camina como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            oeste;
            corre;
            norte;
            si frente-libre entonces inicio
                avanza;
                este;
            fin sino inicio
                sur;
            fin;
        fin;
    fin;
    define-nueva-instruccion resta(x) como inicio
        si no si-es-cero(x) y no-orientado-al-sur entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                camina;
                resta(precede(x));
            fin sino inicio
                camina;
                resta(x);
            fin;
        fin sino inicio
            si si-es-cero(x) entonces inicio
                mientras no-orientado-al-sur y no-junto-a-zumbador hacer camina;
                si junto-a-zumbador entonces inicio
                    sur;
                    corre;
                    oeste;
                    corre;
                fin sino inicio
                    corre;
                    norte;
                fin;
            fin sino inicio
                corre;
                este;
            fin;
        fin;
    fin;
    define-nueva-instruccion cuenta0(x) como inicio
        si no-orientado-al-sur entonces inicio
            si no-junto-a-zumbador entonces inicio
                camina;
                cuenta0(sucede(x));
            fin sino inicio
                camina;
                cuenta0(x);
            fin;
        fin sino inicio
            corre;
            este;
            resta(x);
        fin;
    fin;
    inicia-ejecucion
        este;
        cuenta0(0);
        apagate;
    termina-ejecucion
finalizar-programa
