iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion camina(x) como inicio
        si si-es-cero(precede(x)) entonces inicio
            norte;
        fin;
        si si-es-cero(precede(precede(x))) entonces inicio
            sur;
        fin;
        si si-es-cero(precede(precede(precede(x)))) entonces inicio
            este;
        fin;
        si no-junto-a-zumbador entonces deja-zumbador;
        avanza;
    fin;
    define-nueva-instruccion leer(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            leer(sucede(x));
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    leer(0);
                fin sino inicio
                    este;
                    avanza;
                fin;
                camina(x);
            fin;
        fin;
    fin;
    define-nueva-instruccion regresa(x) como inicio
        si frente-libre entonces inicio
            avanza;
            regresa(x);
            avanza;
        fin sino inicio
            repetir x veces deja-zumbador;
            este;
        fin;
    fin;
    define-nueva-instruccion cuenta(x) como inicio
        si frente-libre entonces inicio
            avanza;
            cuenta(sucede(x));
        fin sino inicio
            oeste;
            regresa(x);
            oeste;
            avanza;
        fin;
    fin;
    define-nueva-instruccion sube como inicio
        mientras frente-libre hacer inicio
            norte;
            mientras no-junto-a-zumbador hacer avanza;
            mientras junto-a-zumbador y frente-libre hacer avanza;
            sur;
            si no-junto-a-zumbador entonces avanza;
            cuenta(1);
        fin;
    fin;
    inicia-ejecucion
        este;
        avanza;
        mientras junto-a-zumbador y frente-libre hacer avanza;
        oeste;
        si no-junto-a-zumbador entonces avanza;
        leer(0);
        oeste;
        si frente-bloqueado entonces inicio
            este;
            avanza;
        fin;
        si no-junto-a-zumbador entonces inicio deja-zumbador; fin;
        oeste;
        sube;
        apagate;
    termina-ejecucion
finalizar-programa
