iniciar-programa

define-nueva-instruccion gira(z) como repetir z veces gira-izquierda;

define-nueva-instruccion pintar(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        pintar(sucede(a));
    fin sino inicio
        avanza;
        si junto-a-zumbador entonces pintar(0);
        si orientado-al-oeste entonces inicio
            gira(2);
            avanza;
            deja-zumbador;
        fin;
        mientras no-orientado-al-norte hacer gira-izquierda;
        si si-es-cero(precede(precede(a))) entonces inicio
            gira(2);
        fin sino si si-es-cero(precede(precede(precede(a)))) entonces inicio
            gira(3);
        fin;
        avanza;
        si no-junto-a-zumbador entonces deja-zumbador;
    fin;
fin;

define-nueva-instruccion contar(a) como inicio
    si orientado-al-sur y frente-libre entonces inicio
        avanza;
        contar(sucede(a));
    fin sino inicio
        si orientado-al-sur entonces inicio
            gira(3);
            avanza;
            gira(3);
        fin;
       si izquierda-libre entonces inicio
           mientras no-junto-a-zumbador hacer avanza;
           mientras junto-a-zumbador y frente-libre hacer avanza;
           gira(2);
           si no-junto-a-zumbador entonces avanza;
           contar(1);
       fin;
       repetir a veces deja-zumbador;
    fin
fin;

    inicia-ejecucion

    mientras no-orientado-al-este hacer gira-izquierda;
    avanza;
    si no-junto-a-zumbador entonces inicio
        deja-zumbador;
    fin sino inicio
        mientras junto-a-zumbador y frente-libre hacer avanza;
        gira(2);
        si no-junto-a-zumbador entonces avanza;
        pintar(0);
    fin;
    mientras no-orientado-al-norte hacer gira-izquierda;
    contar(0);

        apagate;
    termina-ejecucion
finalizar-programa
