iniciar-programa
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion llenar(n) como inicio
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
            fin;
            llenar(sucede(n));
        fin sino inicio
            norte;
            repetir n veces inicio
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion contorno(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            contorno(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    contorno(0);
                fin sino inicio
                    este;
                    avanza;
                    deja-zumbador;
                    deja-zumbador;
                fin;
            fin;
            si si-es-cero (precede(n)) entonces inicio
                norte;
                avanza;
                si no-junto-a-zumbador entonces inicio
                    deja-zumbador;
                    deja-zumbador;
                fin;
            fin;
            si si-es-cero (precede(precede(n))) entonces inicio
                sur;
                avanza;
                si no-junto-a-zumbador entonces inicio
                    deja-zumbador;
                    deja-zumbador;
                fin;
            fin;
            si si-es-cero (precede(precede(precede(n)))) entonces inicio
                sur;
                llenar(0);
                este;
                avanza;
                si no-junto-a-zumbador entonces inicio
                    deja-zumbador;
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion juntar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si frente-libre entonces inicio
                avanza;
            fin;
            juntar(sucede(n));
        fin sino inicio
            sur;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            oeste;
            avanza;
            norte;
            si junto-a-zumbador entonces inicio
                juntar(0);
            fin;
            repetir n veces inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    inicia-ejecucion
        este;
        avanza;
        mientras junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        oeste;
        si frente-bloqueado y no-junto-a-zumbador entonces inicio
            avanza;
        fin;
        contorno(0);
        norte;
        juntar(0);
        apagate;
    termina-ejecucion
finalizar-programa
