iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion iniciar como inicio
        este;
        mientras frente-libre hacer avanza;
        oeste;
        mientras no junto-a-zumbador y frente-libre hacer avanza;
    fin;

    define-nueva-instruccion dejar como inicio
        si frente-libre entonces inicio
            avanza;
            si no junto-a-zumbador entonces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion recoge(n) como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            coge-zumbador;
            recoge(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                recoge(0);
            fin sino inicio
                este;
                avanza;
                deja-zumbador;
            fin;
            si si-es-cero(precede(n)) entonces inicio
                norte;
                dejar;
            fin;
            si si-es-cero(precede(precede(n))) entonces inicio
                sur;
                dejar;
            fin;
            si si-es-cero(precede(precede(precede(n)))) entonces inicio
                este;
                dejar;
            fin;
        fin;
    fin;

    define-nueva-instruccion dejaa(n) como inicio
        si frente-libre entonces inicio
            avanza;
            dejaa(n);
            avanza;
        fin sino inicio
            repetir n veces deja-zumbador;
            este;
        fin;
    fin;

    define-nueva-instruccion final(n) como inicio
        si junto-a-zumbador y no orientado-al-sur entonces inicio
            si frente-libre entonces inicio
                avanza;
                final(sucede(n));
            fin sino inicio
                sur;
            fin;
        fin sino inicio
            sur;
            mientras frente-libre hacer avanza;
            oeste;
            dejaa(n);
        fin;
    fin;

    define-nueva-instruccion final2(n) como inicio
        si frente-libre entonces inicio
            avanza;
            final2(sucede(n));
        fin sino inicio
            oeste;
            dejaa(sucede(n));
        fin;
    fin;

    inicia-ejecucion
        iniciar;
        recoge(0);
        sur;
        mientras frente-libre hacer avanza;
        iniciar;
        norte;
        mientras izquierda-libre hacer inicio
            si junto-a-zumbador entonces inicio
                final(0);
            fin sino inicio
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                mientras junto-a-zumbador y frente-libre hacer avanza;
                si no junto-a-zumbador entonces inicio
                    sur;
                    avanza;
                fin sino inicio
                    sur;
                fin;
                final2(0);
            fin;
            oeste;
            avanza;
            norte;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
