iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion pintura como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si frente-libre entonces inicio
                        avanza;
                        pintura;
                        este;
                        si frente-libre entonces avanza;
                        si no-junto-a-zumbador entonces deja-zumbador;
                    fin;
                fin sino inicio
                    si frente-libre entonces inicio
                        avanza;
                        pintura;
                        sur;
                        si frente-libre entonces avanza;
                        si no-junto-a-zumbador entonces deja-zumbador;
                    fin;
                fin;
            fin sino inicio
                si frente-libre entonces inicio
                    avanza;
                    pintura;
                    norte;
                    si frente-libre entonces avanza;
                    si no-junto-a-zumbador entonces deja-zumbador;
                fin;
            fin;
        fin sino inicio
            este;
            avanza;
            deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion buscar_inicio como inicio
        norte;
        si izquierda-libre entonces inicio
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            mientras junto-a-zumbador y frente-libre hacer avanza;
            sur;
            si no-junto-a-zumbador entonces avanza;
        fin;
    fin;

    define-nueva-instruccion cuenta como inicio
        si frente-libre y orientado-al-sur entonces inicio
            avanza;
            cuenta;
            deja-zumbador;
        fin sino inicio
            oeste;
            si frente-libre entonces inicio
                avanza;
                buscar_inicio;
                cuenta;
                deja-zumbador;
            fin;
        fin;
    fin;

    inicia-ejecucion
        este;
        avanza;
        mientras junto-a-zumbador y frente-libre hacer avanza;
        oeste;
        si no-junto-a-zumbador entonces avanza;
        pintura;
        buscar_inicio;
        cuenta;
        apagate;
    termina-ejecucion
finalizar-programa
