iniciar-programa
    define-nueva-instruccion toma(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            toma(sucede(n));
        fin
        sino inicio
            si frente-libre entonces inicio
                avanza;
                toma(0);
            fin
            sino inicio
                mientras no-orientado-al-este hacer gira-izquierda;
                avanza;
                mientras no-orientado-al-norte hacer gira-izquierda;
            fin;
            si si-es-cero(precede(n)) entonces inicio
                mientras no-orientado-al-norte hacer gira-izquierda;
                si no-junto-a-zumbador entonces deja-zumbador;
                avanza;
            fin;
            si si-es-cero(precede(precede(n))) entonces inicio
                mientras no-orientado-al-sur hacer gira-izquierda;
                si no-junto-a-zumbador entonces deja-zumbador;
                avanza;
            fin;
            si si-es-cero(precede(precede(precede(n)))) entonces inicio
                mientras no-orientado-al-este hacer gira-izquierda;
                si no-junto-a-zumbador entonces deja-zumbador;
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion contorno(n) como inicio
        si frente-libre entonces inicio
            avanza;
            contorno(sucede(n));
            deja-zumbador;
        fin
        sino inicio
            mientras no-orientado-al-norte hacer gira-izquierda;
            mientras frente-libre hacer avanza;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion busca como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-este hacer gira-izquierda;
        avanza;
        mientras no-orientado-al-norte hacer gira-izquierda;
        mientras no-junto-a-zumbador hacer inicio
            si frente-libre entonces inicio
                avanza;
            fin
            sino sal-de-instruccion;
        fin;
        mientras junto-a-zumbador hacer avanza;
        mientras no-orientado-al-sur hacer gira-izquierda;
        avanza;
        contorno(1);
        busca;
    fin;
    define-nueva-instruccion acaba(n) como inicio
        si frente-libre entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                acaba(sucede(n));
                deja-zumbador;
            fin
            sino inicio
                avanza;
                acaba(n);
            fin;
        fin
        sino inicio
            mientras no-orientado-al-sur hacer gira-izquierda;
            mientras frente-libre hacer avanza;
        fin;
    fin;
    inicia-ejecucion
        mientras no-orientado-al-este hacer gira-izquierda;
        avanza;
        mientras junto-a-zumbador y frente-libre hacer avanza;
        repetir 2 veces gira-izquierda;
        avanza;
        toma(0);
        si no-junto-a-zumbador entonces deja-zumbador; 
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        busca;
        mientras no-orientado-al-oeste hacer gira-izquierda;
        avanza;
        acaba(0);
        apagate;
    termina-ejecucion
finalizar-programa
