iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion quita(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            quita(n);
            coge-zumbador;
        fin sino inicio
            repetir n veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion compara2(n) como inicio
        norte;
        repetir n veces inicio
            si junto-a-zumbador y no orientado-al-sur entonces inicio
                coge-zumbador;
            fin sino inicio
                sur;
                deja-zumbador;
            fin;
        fin;
        si orientado-al-norte entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion compara(n) como inicio
        norte;
        repetir n veces inicio
            si junto-a-zumbador y no orientado-al-sur entonces inicio
                coge-zumbador;
            fin sino inicio
                sur;
                deja-zumbador;
            fin;
        fin;
        si orientado-al-norte entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            repetir n veces deja-zumbador;
        fin sino inicio
            quita(n);
        fin;
    fin;

    define-nueva-instruccion dejar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            dejar(sucede(n));
        fin sino inicio
            oeste;
            si frente-libre entonces inicio
                avanza;
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                si no junto-a-zumbador entonces inicio
                    norte;
                    mientras no junto-a-zumbador y frente-libre hacer avanza;
                    compara2(n);
                    apagate;
                fin sino inicio
                    compara2(n);
                    apagate;
                fin;
            fin sino inicio
                norte;
                avanza;
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                compara2(n);
                apagate;
            fin;
        fin;
    fin;

    define-nueva-instruccion busqueda(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    repetir 2 veces deja-zumbador;
                    compara(sucede(sucede(n)));
                fin sino inicio
                    repetir 2 veces deja-zumbador;
                fin;
            fin sino inicio
                repetir sucede(sucede(n)) veces deja-zumbador;
            fin;
        fin sino inicio
            repetir 2 veces deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                sur;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                norte;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                oeste;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                este;
                avanza;
            fin;
            repetir 2 veces coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion quita2 como inicio
        mientras no orientado-al-sur hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        repetir 2 veces deja-zumbador;
                        si frente-libre entonces inicio
                            avanza;
                        fin sino inicio
                            sur;
                        fin;
                    fin sino inicio
                        si frente-libre entonces inicio
                            avanza;
                        fin sino inicio
                            sur;
                        fin;
                    fin;
                fin sino inicio
                    deja-zumbador;
                    si frente-libre entonces inicio
                        avanza;
                    fin sino inicio
                        sur;
                    fin;
                fin;
            fin;
        fin;
        sur;
        mientras no junto-a-zumbador y frente-libre hacer avanza;
        norte;
        repetir 2 veces coge-zumbador;
    fin;

    define-nueva-instruccion puma(n) como inicio
        si frente-libre entonces inicio
            avanza;
            puma(sucede(n));
        fin sino inicio
            este;
            si frente-libre entonces inicio
                avanza;
                puma(sucede(n));
            fin sino inicio
                sur;
                mientras frente-libre hacer avanza;
                si junto-a-zumbador entonces inicio
                    compara(n);
                    dejar(0);
                fin sino inicio
                    repetir n veces deja-zumbador;
                    oeste;
                    si frente-libre entonces inicio
                        avanza;
                        mientras no junto-a-zumbador y frente-libre hacer avanza;
                        si no junto-a-zumbador entonces inicio
                            norte;
                            mientras no junto-a-zumbador y frente-libre hacer avanza;
                            sur;
                            puma(0);
                        fin sino inicio
                            sur;
                            puma(0);
                        fin;
                    fin sino inicio
                        norte;
                        avanza;
                        mientras no junto-a-zumbador y frente-libre hacer avanza;
                        sur;
                        puma(0);
                    fin;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion busca como inicio
        mientras no junto-a-zumbador hacer inicio
            si derecha-bloqueada y frente-libre entonces inicio
                avanza;
            fin sino inicio
                si derecha-bloqueada y frente-bloqueado entonces inicio
                    gira-izquierda;
                fin sino inicio
                    si derecha-libre entonces inicio
                        repetir 3 veces gira-izquierda;
                        avanza;
                    fin;
                fin;
            fin;
        fin;
        este;
        si frente-bloqueado y izquierda-bloqueada y derecha-bloqueada entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            apagate;
        fin;

        sur;
        mientras frente-libre hacer avanza;
        norte;
        quita2;
        puma(0);
    fin;

    define-nueva-instruccion regresa como inicio
        mientras no junto-a-zumbador hacer inicio
            si izquierda-bloqueada y frente-libre entonces inicio
                avanza;
            fin sino inicio
                si izquierda-bloqueada y frente-bloqueado entonces inicio
                    repetir 3 veces gira-izquierda;
                fin sino inicio
                    si izquierda-libre entonces inicio
                        gira-izquierda;
                        avanza;
                    fin;
                fin;
            fin;
        fin;
        coge-zumbador;
    fin;

    define-nueva-instruccion acomodar como inicio
        si orientado-al-norte entonces inicio
            mientras frente-libre hacer inicio
                avanza;
                repetir 2 veces deja-zumbador;
            fin;
            si frente-bloqueado entonces inicio
                sur;
                mientras junto-a-zumbador y frente-libre hacer avanza;
                si no junto-a-zumbador entonces inicio
                    norte;
                    avanza;
                    sur;
                fin;
            fin;
        fin sino inicio
            norte;
            mientras no orientado-al-oeste hacer inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si no junto-a-zumbador entonces inicio
                        deja-zumbador;
                        oeste;
                        avanza;
                    fin;
                fin sino inicio
                    repetir 2 veces deja-zumbador;
                    avanza;
                fin;
            fin;
        fin;
    fin;


    define-nueva-instruccion iniciar como inicio
        mientras no junto-a-zumbador o no orientado-al-este  hacer inicio
            si derecha-bloqueada y frente-libre entonces inicio
                avanza;
            fin sino inicio
                si derecha-bloqueada y frente-bloqueado entonces inicio
                    gira-izquierda;
                fin sino inicio
                    si derecha-libre entonces inicio
                        repetir 3 veces gira-izquierda;
                        avanza;
                    fin;
                fin;
            fin;
        fin;
        norte;
        acomodar;
        mientras frente-libre hacer avanza;
        acomodar;
    fin;

    inicia-ejecucion
        deja-zumbador;
        mientras derecha-libre hacer gira-izquierda;
        si derecha-bloqueada y frente-libre entonces inicio
                avanza;
            fin sino inicio
                si derecha-bloqueada y frente-bloqueado entonces inicio
                    gira-izquierda;
                    si derecha-bloqueada y frente-bloqueado entonces inicio
                        gira-izquierda;
                        si derecha-bloqueada y frente-bloqueado entonces inicio
                            gira-izquierda;
                            avanza;
                        fin sino inicio
                            avanza;
                        fin;
                    fin sino inicio
                        avanza;
                    fin;
                fin sino inicio
                    si derecha-libre entonces inicio
                        repetir 3 veces gira-izquierda;
                        avanza;
                    fin;
                fin;
            fin;
        iniciar;
        regresa;
        busqueda(0);
        mientras derecha-libre hacer gira-izquierda;
        busca;
        apagate;
    termina-ejecucion
finalizar-programa
