iniciar-programa
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion compara(n) como inicio
        si junto-a-zumbador y no si-es-cero (n) entonces inicio
            coge-zumbador;
            compara(precede(n));
            deja-zumbador;
        fin sino inicio
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion busqueda(n) como inicio
        si no-junto-a-zumbador entonces inicio
            deja-zumbador;
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                sur;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                norte;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                oeste;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                este;
                avanza;
            fin;
            coge-zumbador;
            coge-zumbador;
        fin sino inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        compara(n);
                        deja-zumbador;
                        deja-zumbador;
                    fin sino inicio
                        deja-zumbador;
                        deja-zumbador;
                    fin;
                fin sino inicio
                    deja-zumbador;
                    deja-zumbador;
                    repetir n veces inicio
                        deja-zumbador;
                    fin;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion gira-derecha como inicio
        repetir 3 veces inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion encontrar como inicio
        mientras derecha-bloqueada y frente-libre y no-junto-a-zumbador hacer inicio
            avanza;
        fin;
        si no-junto-a-zumbador entonces inicio
            si derecha-libre entonces inicio
                gira-derecha;
                avanza;
                encontrar;
            fin sino inicio
                gira-izquierda;
                encontrar;
            fin;
        fin;
    fin;
    define-nueva-instruccion encontrarcasa como inicio
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        gira-izquierda;
        encontrar;
    fin;
    define-nueva-instruccion compararmenor(n) como inicio
        si junto-a-zumbador y no si-es-cero (n) entonces inicio
            coge-zumbador;
            compararmenor(precede(n));
            deja-zumbador;
        fin sino inicio
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion contar(n) como inicio
        si frente-libre entonces inicio
            avanza;
            contar(sucede(n));
        fin sino inicio
            gira-izquierda;
            gira-izquierda;
            mientras no-junto-a-zumbador hacer inicio
                avanza;
            fin;
            oeste;
            avanza;
            si no-junto-a-zumbador y no si-es-cero(n) entonces inicio
                repetir n veces inicio
                    deja-zumbador;
                fin;
                este;
                avanza;
                sur;
            fin sino inicio
                compararmenor(n);
            fin;
        fin;
    fin;
    define-nueva-instruccion contarnortesur(n) como inicio
        si frente-libre entonces inicio
            avanza;
            contarnortesur(sucede(n));
        fin sino inicio
            oeste;
            repetir n veces inicio
                avanza;
            fin;
            norte;
            contar(n);
            contar(n);
        fin;
    fin;
    define-nueva-instruccion llevalos como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            llevalos;
            deja-zumbador;
        fin sino inicio
            este;
            avanza;
        fin;
    fin;
    define-nueva-instruccion cogeresta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cogeresta(sucede(n));
        fin sino inicio
            oeste;
            avanza;
            repetir n veces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin;
            fin;
            si junto-a-zumbador entonces inicio
                llevalos;
            fin;
        fin;
    fin;
    define-nueva-instruccion restar como inicio
        este;
        avanza;
        coge-zumbador;
        coge-zumbador;
        cogeresta(0);
    fin;
    inicia-ejecucion
        busqueda(0);
        encontrarcasa;
        contarnortesur(0);
        restar;
        apagate;
    termina-ejecucion
finalizar-programa
