iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-prototipo-instruccion tiempoC(x);
    define-nueva-instruccion compara(x) como inicio
        si junto-a-zumbador y no si-es-cero(x) entonces inicio
            coge-zumbador;
            compara(precede(x));
            deja-zumbador;
        fin sino inicio
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion camina(x) como inicio
        norte;
        si frente-libre entonces inicio
            avanza;
            tiempoC(x);
            sur;
            avanza;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            tiempoC(x);
            oeste;
            avanza;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            tiempoC(x);
            norte;
            avanza;
        fin;
        oeste;
        si frente-libre entonces inicio
            avanza;
            tiempoC(x);
            este;
            avanza;
        fin;
    fin;
    define-nueva-instruccion tiempoC(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    compara(x);
                    repetir 2 veces deja-zumbador;
                fin sino inicio
                    repetir 2 veces deja-zumbador;
                fin;
            fin sino inicio
                repetir x veces deja-zumbador;
                repetir 2 veces deja-zumbador;
            fin;
        fin sino inicio
            repetir 2 veces deja-zumbador;
            camina(sucede(x));
            repetir 2 veces coge-zumbador;
        fin;
    fin;
    define-prototipo-instruccion ve-casa;
    define-nueva-instruccion resta-tiempo(x) como inicio
        si frente-libre y no si-es-cero(x) entonces inicio
            avanza;
            resta-tiempo(precede(x));
        fin sino inicio
            norte;
            mientras no-junto-a-zumbador hacer avanza;
            si si-es-cero(x) entonces inicio
                norte;
            fin sino inicio
                sur;
            fin;
        fin;
    fin;
    define-nueva-instruccion resta-final(x) como inicio
        si junto-a-zumbador y  no si-es-cero(x) entonces inicio
            coge-zumbador;
            resta-final(precede(x));
        fin sino inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            repetir x veces deja-zumbador;
            apagate;
        fin;
    fin;
    define-nueva-instruccion regresa-casa(x) como inicio
        si no-junto-a-zumbador y frente-libre entonces inicio
            avanza;
            regresa-casa(sucede(x));
        fin sino inicio
            resta-final(x);
        fin;
    fin;
    define-nueva-instruccion cuenta-min(x) como inicio
        si frente-libre  entonces inicio
            avanza;
            cuenta-min(sucede(x));
        fin sino inicio
            repetir 2 veces gira-izquierda;
            mientras no-junto-a-zumbador hacer avanza;
            oeste;
            coge-zumbador;
            regresa-casa(x);
        fin;
    fin;
    define-nueva-instruccion tiempoP(x) como inicio
        si frente-libre entonces inicio
            avanza;
            tiempoP(sucede(x));
        fin sino inicio
            sur;
            mientras no-junto-a-zumbador hacer avanza;
            resta-tiempo(x);
            cuenta-min(0);
        fin;
    fin;
    define-nueva-instruccion cambia como inicio
        norte;
        si frente-libre entonces inicio
            avanza;
            ve-casa;
            sur;
            avanza;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            ve-casa;
            oeste;
            avanza;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            ve-casa;
            norte;
            avanza;
        fin;
        oeste;
        si frente-libre entonces inicio
            avanza;
            ve-casa;
            este;
            avanza;
        fin;
    fin;
    define-nueva-instruccion limpia como inicio
        sur;
        corre;
        norte;
        mientras no orientado-al-sur hacer inicio
            si junto-a-zumbador entonces coge-zumbador;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                sur;
            fin;

        fin;
        mientras no-junto-a-zumbador hacer avanza;
    fin;
    define-nueva-instruccion ve-casa como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                este;
                si frente-bloqueado entonces inicio
                    norte;
                    deja-zumbador;
                    tiempoP(0);
                fin sino inicio
                    mientras frente-libre hacer inicio
                        avanza;
                        si junto-a-zumbador entonces coge-zumbador;
                    fin;
                    repetir 2 veces deja-zumbador;
                    limpia;
                    norte;
                    tiempoP(0);
                fin;
            fin sino inicio
                deja-zumbador;
            fin;
        fin sino inicio
            deja-zumbador;
            cambia;
        fin;
    fin;

    inicia-ejecucion
        tiempoC(0);
        ve-casa;

        apagate;
    termina-ejecucion
finalizar-programa
